UDF > FTPEx >

_FTP_Connect

Se connecte à un serveur FTP

#include <FTPEx.au3>
_FTP_Connect ( $hInternetSession, $sServerName, $sUsername, $sPassword [, $iPassive = 0 [, $iServerPort = 0 [, $iService = $INTERNET_SERVICE_FTP [, $iFlags = $INTERNET_FLAG_DEFAULT [, $fuContext = 0]]]]] )

Paramètres

$hInternetSession Handle retourné par _FTP_Open()
$sServerName Nom ou IP du serveur.
$sUsername Nom d'utilisateur.
$sPassword Mot de passe.
$iPassive [optionnel] Mode passif. Par défaut 0. Voir Remarques.
$iServerPort [optionnel] Port du serveur (0 par défaut (21))
$iService [optionnel] Peut prendre l'une des valeurs constantes suivantes:
    $INTERNET_SERVICE_FTP (1)- Service FTP.
    $INTERNET_SERVICE_GOPHER (2)- Service Gopher. Disponible uniquement sur Windows X​P, Windows Server 2003 R2 ou une version ultérieure.
    $INTERNET_SERVICE_HTTP (3)- services HTTP.
$iFlags [optionnel] Flags spéciaux.
    $INTERNET_FLAG_DEFAULT (0)
    $INTERNET_FLAG_PASSIVE (0x08000000)(
    $INTERNET_FLAG_TRANSFER_ASCII (1)
    $INTERNET_FLAG_TRANSFER_BINARY (2)
$fuContext [optionnel] Une variable qui contient la valeur définie par l'application qui associe cette recherche avec les données de l'application.
Ceci n'est utilisé que si l'application a déjà appelé _FTP_SetStatusCallback() pour définir le status d'une foncion de rappel.

Valeur de retour

Succès: Retourne le handle de la session connectée.
Échec: Retourne 0 et définit @error <> 0.

Remarque

Le handle retourné doit être fermé avec _FTP_Close().
Si $iPassive est défini à 1, alors le flag spécial $INTERNET_FLAG_PASSIVE est automatiquement combiné le paramètre $iFlag de l'utilisateur.

En relation

_FTP_Close, _FTP_Command, _FTP_DirCreate, _FTP_DirDelete, _FTP_DirGetCurrent, _FTP_DirPutContents, _FTP_DirSetCurrent, _FTP_FileDelete, _FTP_FileGet, _FTP_FileGetSize, _FTP_FilePut, _FTP_FileRename, _FTP_ListToArray, _FTP_ListToArray2D, _FTP_ListToArrayEx, _FTP_Open, _FTP_SetStatusCallback

Voir aussi

Consultez InternetConnect dans la librairie MSDN.

Exemple

#include <FTPEx.au3>
#include <MsgBoxConstants.au3>

_Example()

Func _Example()
    Local $sServer = 'ftp.csx.cam.ac.uk' ; UNIVERSITY OF CAMBRIDGE ANONYMOUS FTP SERVER
    Local $sUsername = ''
    Local $sPass = ''
    Local $Err, $sFTP_Message

    Local $hOpen = _FTP_Open('MyFTP Control')
    Local $hConn = _FTP_Connect($hOpen, $sServer, $sUsername, $sPass)
    If @error Then
        MsgBox($MB_SYSTEMMODAL, '_FTP_Connect', 'ERREUR=' & @error)
    Else
        _FTP_GetLastResponseInfo($Err, $sFTP_Message)
        ConsoleWrite('$Err=' & $Err & '   $sFTP_Message:' & @CRLF & $sFTP_Message & @CRLF)
        ; Faire quelque chose ...
    EndIf
    Local $iFtpc = _FTP_Close($hConn)
    Local $iFtpo = _FTP_Close($hOpen)
EndFunc   ;==>_Example