UDF > Date >

_Date_Time_FileTimeToSystemTime

Convertit une date/heure de fichier au format de la date/heure système

#include <Date.au3>
_Date_Time_FileTimeToSystemTime ( $tFileTime )

Paramètre

$tFileTime Structure $tagFILETIME contenant l'heure du fichier à convertir au format de date et d'heure système ou un pointeur vers elle.

Valeur de retour

Retourne une structure $tagSYSTEMTIME qui contient l'heure convertie du fichier.

En relation

$tagFILETIME, $tagSYSTEMTIME, _Date_Time_FileTimeToDOSDateTime, _Date_Time_FileTimeToLocalFileTime

Exemple

#include <Date.au3>
#include <FontConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tFile, $tSystem

    ; Crée la GUI
    GUICreate("Temps", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, $FW_NORMAL, $GUI_FONTNORMAL, "Courier New")
    GUISetState(@SW_SHOW)

    ; Encode une heure de fichier
    $tFile = _Date_Time_EncodeFileTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC)
    $tSystem = _Date_Time_FileTimeToSystemTime($tFile)
    MemoWrite("Heure de fichier au format de l'heure système . : " & _Date_Time_SystemTimeToDateTimeStr($tSystem))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite