UDF > Date >


_Date_Time_FileTimeToDOSDateTime

Convertit les valeurs date/heure MS-DOS en date/heure de fichier

#include <Date.au3>
_Date_Time_FileTimeToDOSDateTime ( $tFileTime )

Paramètre

$tFileTime Une structure $tagFILETIME contenant l'heure du fichier à convertir au format MS-DOS ou un pointeur vers elle

Valeur de retour

Retourne un tableau (array) au format suivant:
[0] - Date MS-DOS, codée comme suit:
   Bits 0-4 Jour du mois (1–31)
   Bits 5-8 Mois (1 = janvier, 2 = février, et ainsi de suite)
   Bits 9-15 Décalage de l'année par rapport à 1980 (ajoutez 1980 pour obtenir l'année actuelle)
[1] - Heure MS-DOS, codée comme suit:
   Bits 0-4 Seconde divisée par 2
   Bits 5-10 Minute (0–59)
   Bits 11-15 Heure (0–23 sur une horloge de 24 heures)

En relation

$tagFILETIME, _Date_Time_DOSDateTimeToFileTime, _Date_Time_FileTimeToLocalFileTime, _Date_Time_FileTimeToSystemTime

Exemple

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tFile, $aDOS

    ; Crée la GUI
    GUICreate("Temps", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Encode une heure de fichier
    $tFile = _Date_Time_EncodeFileTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC)
    $aDOS = _Date_Time_FileTimeToDOSDateTime($tFile)
    MemoWrite("Date DOS. : 0x" & Hex($aDOS[0], 4))
    MemoWrite("Heure DOS. : 0x" & Hex($aDOS[1], 4))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite