UDF > Date >

_Date_Time_FileTimeToLocalFileTime

Convertit une date/heure de fichier basée sur le temps universel coordonné (UTC) en une date/heure locale de fichier

#include <Date.au3>
_Date_Time_FileTimeToLocalFileTime ( $tFileTime )

Paramètre

$tFileTime Une structure $tagFILETIME contenant la date/heure d'un fichier, basée sur l'heure UTC, pour être convertie en une heure locale de fichier ou un pointeur vers elle.

Valeur de retour

Retourne une structure $tagFILETIME qui contient l'heure convertie du fichier.

En relation

$tagFILETIME, _Date_Time_FileTimeToDOSDateTime, _Date_Time_FileTimeToSystemTime, _Date_Time_LocalFileTimeToFileTime

Exemple

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tFile, $tLocal

    ; Crée la GUI
    GUICreate("Temps", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Récupère l'heure système
    Local $tSystem = _Date_Time_GetSystemTime()
    $tFile = _Date_Time_SystemTimeToFileTime($tSystem)
    ;   --------------------------------------
    $tLocal = _Date_Time_FileTimeToLocalFileTime($tFile)
    MemoWrite("Heure locale du fichier . : " & _Date_Time_FileTimeToStr($tLocal))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite