UDF > Date >

_Date_Time_SystemTimeToDateTimeStr

Décode une date/heure système en une chaîne contenant date/heure

#include <Date.au3>
_Date_Time_SystemTimeToDateTimeStr ( ByRef $tSYSTEMTIME [, $iFmt = 0] )

Paramètres

$tSYSTEMTIME Structure $tagSYSTEMTIME
$iFmt [optionnel] 0 pour le format mm/dd/aaaa hh:mm:ss (par défaut)
1 pour le format aaaa/mm/dd hh:mm:ss

Valeur de retour

Retourne une date/heure sous forme d'une chaîne formatée selon $iFmt.

En relation

$tagSYSTEMTIME, _Date_Time_SystemTimeToDateStr, _Date_Time_SystemTimeToTimeStr

Exemple

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tTime

    ; Crée la GUI
    GUICreate("Temps", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Affiche la date/heure système
    $tTime = _Date_Time_GetSystemTime()
    MemoWrite("Date/heure du système . : " & _Date_Time_SystemTimeToDateTimeStr($tTime))
    MemoWrite("Date/heure du système . : " & _Date_Time_SystemTimeToDateTimeStr($tTime, 1))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite