UDF > Date >

_Date_Time_LocalFileTimeToFileTime

Convertit date/heure locale d'un fichier en date/heure UTC

#include <Date.au3>
_Date_Time_LocalFileTimeToFileTime ( $tLocalTime )

Paramètre

$tLocalTime Structure $tagFILETIME qui spécifie l'heure locale d'un fichier pour être convertie en une heure de fichier basée sur UTC ou un pointeur vers elle.

Valeur de retour

Retourne une structure $tagFILETIME avec l'heure du fichier convertie en UTC.

Remarque

Cette fonction utilise les paramètres actuels pour le fuseau horaire et l'heure d'été. Par conséquent, si c'est l'heure d'été, cette fonction prendra en compte l'heure d'été, même si le temps que vous êtes en train de convertir est en heure d'hiver.

En relation

$tagFILETIME, _Date_Time_FileTimeToLocalFileTime

Exemple

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tTime, $tLocal

    ; Crée la GUI
    GUICreate("Temps", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Affiche la date/heure locale en UTC
    $tTime = _Date_Time_EncodeFileTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC)
    $tLocal = _Date_Time_LocalFileTimeToFileTime($tTime)
    MemoWrite("Date/heure locale . : " & _Date_Time_FileTimeToStr($tLocal))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite