UDF > Date >

_Date_Time_DOSDateTimeToFileTime

Convertit les valeurs de date/heure MS-DOS en date/heure de fichier

#include <Date.au3>
_Date_Time_DOSDateTimeToFileTime ( $iFatDate, $iFatTime )

Paramètres

$iFatDate La date de MS-DOS, codée comme ceci:
Bits 0-4 Jour du mois (1–31)
Bits 5-8 Mois (1 = janvier, 2 = février, et ainsi de suite)
Bits 9-15 Décalage de l'année par rapport à 1980 (ajoutez 1980 pour obtenir l'année actuelle)
$iFatTime L'heure MS-DOS, codée comme ceci:
Bits 0-4 Seconde divisée par 2
Bits 5-10 Minute (0–59)
Bits 11-15 Heure (0–23 sur une horloge de 24 heures)

Valeur de retour

Retourne une structure $tagFILETIME qui reçoit l'heure conventie du fichier.

En relation

$tagFILETIME, _Date_Time_FileTimeToDOSDateTime

Exemple

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tFileTime1, $tFileTime2

    ; Crée la GUI
    GUICreate("Temps", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Compare les Dates/Heures FAT
    $tFileTime1 = _Date_Time_DOSDateTimeToFileTime(0x3621, 0x11EF) ; 01/01/2007 02:15:30
    $tFileTime2 = _Date_Time_DOSDateTimeToFileTime(0x379F, 0x944A) ; 12/31/2007 18:34:20

    MemoWrite("Résultat 1 : " & _Date_Time_CompareFileTime($tFileTime1, $tFileTime2))
    MemoWrite("Résultat 2 : " & _Date_Time_CompareFileTime($tFileTime1, $tFileTime1))
    MemoWrite("Résultat 3 : " & _Date_Time_CompareFileTime($tFileTime2, $tFileTime1))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite