UDF > Clipboard >

_ClipBoard_RegisterFormat

Enregistre un nouveau format de presse-papiers

#include <Clipboard.au3>
_ClipBoard_RegisterFormat ( $sFormat )

Paramètre

$sFormat Le nom du nouveau format

Valeur de retour

Succès: Retourne le format enregistré de presse-papiers
Échec: Retourne 0

Remarque

Si un format enregistré avec le nom spécifié existe déjà, le nouveau format n'est pas enregistré et la valeur de retour identifie le format existant. Cela permet à plus d'une application de copier et coller des données en utilisant le même format enregistré de presse-papiers. Notez que la comparaison des noms de format n'est pas sensible à la casse.

En relation

_ClipBoard_EnumFormats

Voir aussi

Consultez RegisterClipboardFormat dans la Librairie MSDN.

Exemple

#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIError.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $iFormat

    ; Crée une GUI
    GUICreate("Clipboard", 600, 400)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Crée un nouveau format de presse-papiers
    $iFormat = _ClipBoard_RegisterFormat("AutoIt Library Text")
    If $iFormat <> 0 Then

        ; Montre le nouveau format
        MemoWrite(_ClipBoard_GetFormatName($iFormat))
    Else
        _WinAPI_ShowError("_ClipBoard_RegisterFormat failed")
    EndIf

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite