Functions > GUI > GUICtrlCreate >

GUICtrlCreateUpdown

Crée un contrôle UpDown pour une GUI.

GUICtrlCreateUpdown ( inputcontrolID [, style = -1] )

Paramètres

inputcontrolID	Le controlID du contrôle d'entrée dans lequel le contrôle updown sera créé, ou -1 pour le dernier contrôle créé.
style	[optionnel] Définit le style du contrôle. Consultez Annexe des styles des contrôles GUI . Par défaut (-1) : $UDS_ALIGNRIGHT. Styles forcés: $UDS_SETBUDDYINT et $UDS_ALIGNRIGHT si aucun alignement n'est défini.

Valeur de retour

Succès:	Retourne l'ID du nouveau contrôle.
Échec:	Retourne 0.

Remarques

Pour utiliser les valeurs spécifiées ci-dessus, vous devez ajouter #include <UpDownConstants.au3> dans votre script.

Les valeurs minimun et maximum peuvent être définies avec GUICtrlSetLimit() .
Par défaut, Windows incrémente la valeur lors d'un clic sur le bouton flèche vers le haut.
Par défaut le redimensionnement de la hauteur se fait avec le contrôle d'entrée qui contient le contrôle UpDown.

En relation

GUICtrlCreateInput, GUICtrlSetData, GUICtrlSetLimit

Exemple

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    GUICreate("My GUI UpDown", -1, -1, -1, -1, $WS_SIZEBOX)

    Local $idInput = GUICtrlCreateInput("2", 10, 10, 50, 20)
    GUICtrlCreateUpdown($idInput)

    ; Tente de redimensionner le contrôle d'entrée
    GUICtrlSetPos($idInput, 10, 10, 100, 40)

    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    MsgBox($MB_SYSTEMMODAL, "Updown", GUICtrlRead($idInput))
EndFunc   ;==>Example