Functions > GUI > GUICtrlCreate >


GUICtrlCreateIcon

Crée un contrôle Icon pour une GUI.

GUICtrlCreateIcon ( filename, iconName, left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

Paramètres

filename Nom du fichier contenant l'icône à charger.
iconName Nom de l'icône, si le fichier contient plusieurs icônes. Peut être un nom ordinal en cas de nombre négatif. Sinon -1.
left Coordonnée X du coin supérieur gauche du contrôle. Si -1 est utilisé alors X sera automatiquement déterminée par GUICoordMode.
top Coordonnée Y du coin supérieur gauche du contrôle. Si -1 est utilisé alors Y sera automatiquement déterminée par GUICoordMode.
width [optionnel] Largeur du contrôle (32 par défaut).
height [optionnel] Hauteur du contrôle (32 par défaut).
style [optionnel] Définit le style du contrôle. Consultez Annexe des styles des contrôles GUI.
    Par défaut (-1) : $SS_NOTIFY
    Styles forcés : $WS_TABSTOP, $SS_ICON
exStyle [optionnel] Définit le style étendu du contrôle. Consultez Table des styles étendus.

Valeur de retour

Succès: Retourne l'ID du nouveau contrôle.
Échec: Retourne 0.

Remarques

Pour définir ou modifier des informations dans le contrôle, consultez GUICtrlUpdate....

Pour mettre à jour l'icône après l'affichage de la boite de dialogue utilisez GUICtrlSetImage

IconName peut indiquer le numéro du groupe d'icônes. Utilisez un hacker de ressources pour connaître la valeur.

Pour combiner des styles avec le style par défaut utilisez BitOR($GUI_SS_DEFAULT_ICON, newstyle,...).
Pour utiliser les valeurs spécifiées ci-dessus vous devez inclure #include <StaticConstants.au3> dans votre script.

Redimensionnement par défaut : $GUI_DOCKSIZE.

Passer un nombre positif référencera la chaîne équivalente au nom de l'icône.
Passer un nombre négatif impliquera un "index" de base 1. Certaines DLL peuvent avoir une icône extraite seulement avec un nombre négatif.

En relation

GUICoordMode (Option), GUICtrlSetImage, GUICtrlUpdate..., GUIGetMsg

Exemples

Exemple 1

#include <GUIConstantsEx.au3>

Example()

Func Example()
    GUICreate(" My GUI Icons", 250, 250)

    GUICtrlCreateIcon("shell32.dll", 10, 20, 20)
    GUICtrlCreateIcon(@ScriptDir & '\Extras\horse.ani', -1, 20, 40, 32, 32)
    GUICtrlCreateIcon("shell32.dll", 7, 20, 75, 32, 32)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example


Exemple 2

Example()

Func Example()
    Local $iOldOpt = Opt("GUICoordMode", 1)

    GUICreate("My GUI icon Race", 350, 74, -1, -1)
    GUICtrlCreateLabel("", 331, 0, 1, 74, 5)
    Local $id1 = GUICtrlCreateIcon(@ScriptDir & '\Extras\dinosaur.ani', -1, 0, 0, 32, 32)
    Local $id2 = GUICtrlCreateIcon(@ScriptDir & '\Extras\horse.ani', -1, 0, 40, 32, 32)

    GUISetState(@SW_SHOW)

    Local $a = 0
    Local $b = 0
    While ($a < 300) And ($b < 300)
        $a = $a + Int(Random(0, 1) + 0.5)
        $b = $b + Int(Random(0, 1) + 0.5)
        GUICtrlSetPos($id1, $a, 0)
        GUICtrlSetPos($id2, $b, 40)
        Sleep(10)
    WEnd
    Sleep(3000)
    Opt("GUICoordMode", $iOldOpt)
EndFunc   ;==>Example