Functions > GUI > GUICtrlUpdate >

GUICtrlSetPos

Change la position d'un contrôle dans la GUI.

GUICtrlSetPos ( controlID, left [, top [, width [, height]]] )

Paramètres

controlID L'ID du contrôle tel que retourné par une fonction GUICtrlCreate...(), ou -1 pour désigner le dernier contrôle créé.
left La coordonnée X du coin supérieur gauche du contrôle.
top [optionnel] La coordonnée Y du coin supérieur gauche du contrôle.
width [optionnel] La largeur du contrôle.
height [optionnel] La hauteur du contrôle.

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0.

Remarque

Si le mot-clé Default est utilisé en tant que paramètre, la valeur courante n'est pas modifiée.

En relation

GUICtrlCreate...

Exemples

Exemple 1

#include <GUIConstantsEx.au3>

Example()

Func Example()

    GUICreate("My GUI position") ; Crée une GUI centrée

    GUISetFont(16)
    Local $idLabel = GUICtrlCreateLabel("my moving label", 10, 20)

    GUISetState(@SW_SHOW)

    Local $idMsg = GUIGetMsg(), $bToggle = False
    While $idMsg <> $GUI_EVENT_CLOSE
        $bToggle = Not $bToggle
        If $bToggle Then
            GUICtrlSetPos($idLabel, 20, 20)
        Else
            GUICtrlSetPos($idLabel, 20, 30)
        EndIf
        Sleep(160)
        $idMsg = GUIGetMsg()        
    WEnd
EndFunc   ;==>Example

Exemple 2

#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $iOldOpt = Opt("GUICoordMode", 1)

    Local $hGUI = GUICreate("My GUI icon Race", 350, 74, -1, -1)
    GUICtrlCreateLabel("", 331, 0, 1, 74, 5)
    Local $idIcon1 = GUICtrlCreateIcon(@ScriptDir & '\Extras\dinosaur.ani', -1, 0, 0, 32, 32)
    Local $idIcon2 = GUICtrlCreateIcon(@ScriptDir & '\Extras\horse.ani', -1, 0, 40, 32, 32)

    GUISetState(@SW_SHOW)

    Local $a = 0, $b = 0
    While ($a < 300) And ($b < 300)
        $a += Random(0, 1, 1)
        $b += Random(0, 1, 1)
        GUICtrlSetPos($idIcon1, $a, 0)
        GUICtrlSetPos($idIcon2, $b, 40)
        Sleep(10)
    WEnd
    Opt("GUICoordMode", $iOldOpt)
    If $a > $b Then
        MsgBox($MB_SYSTEMMODAL, 'Race results', 'The dinosaur won', 0, $hGUI)
    Else
        MsgBox($MB_SYSTEMMODAL, 'Race results', 'The horse won', 0, $hGUI)
    EndIf
EndFunc   ;==>Example