Fonction _WinAPI_FlashWindowEx

#include <WinAPISysWin.au3>
_WinAPI_FlashWindowEx ( $hWnd [, $iFlags = 3 [, $iCount = 3 [, $iTimeout = 0]]] )

Paramètres

Valeur de retour

Remarque

En règle générale, vous faites clignoter une fenêtre pour informer l'utilisateur que la fenêtre nécessite son attention, mais ne dispose pas actuellement du focus clavier.
Lorsqu'une fenêtre clignote, il apparaît changer de l'état inactif à l'état actif.
Une barre de titre inactive change en une barre de titre active; une barre de titre active se transforme en une barre de titre inactive.

En relation

Voir aussi

Exemple

#include <GUIConstantsEx.au3>
#include <WinAPISysWin.au3>

Example()

Func Example()
    Local $hWnd, $idFlash, $idTimeout, $idBtnFlash, $iMsg, $iFlashrate, $iTimeoutrate, $bFlashing = False
    $hWnd = GUICreate("Form1", 229, 170, 193, 125)
    $idFlash = GUICtrlCreateInput("20", 80, 72, 121, 21)
    $idTimeout = GUICtrlCreateInput("500", 80, 103, 121, 21)
    GUICtrlCreateLabel("Please input the flash rate, and the time between flashes", 8, 24, 214, 41)
    GUICtrlCreateLabel("Flash Rate:", 16, 72, 58, 17)
    GUICtrlCreateLabel("Timeout (ms)", 16, 104, 64, 17)
    $idBtnFlash = GUICtrlCreateButton("Flash Window", 80, 136, 75, 25, 0)
    GUISetState(@SW_SHOW)

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
         If $iMsg = $idBtnFlash Then
            If $bFlashing Then
                _WinAPI_FlashWindowEx($hWnd, 0)
                $bFlashing = False
            Else
                $iFlashrate = GUICtrlRead($idFlash)
                $iTimeoutrate = GUICtrlRead($idTimeout)
                _WinAPI_FlashWindowEx($hWnd, 2, $iFlashrate, $iTimeoutrate)
                GUICtrlSetData($idBtnFlash, "Stop Flashing")
                $bFlashing = True
            EndIf
        EndIf
        $iMsg = GUIGetMsg()
    WEnd
EndFunc   ;==>Example

Succès:	Retourne True
Échec:	Retourne False

$hWnd	Handle de la fenêtre à faire clignoter. La fenêtre peut être ouverte ou réduite.
$iFlags	[optionnel] L'état du clignotement. Peut prendre une ou plusieurs des valeurs suivantes: 0 - Arrête le clignotement. Le système restaure la fenêtre à son état d'origine. 1 - Fait clignoter le titre de la fenêtre 2 - Fait clignoter le bouton de la barre des tâches 4 - Fait clignoter en continu jusqu'à l'arrêt 8 - Fait clignoter en continu jusqu'à ce que la fenêtre soit au premier plan
$iCount	[optionnel] Nombre de fois que la fenêtre doit clignoter
$iTimeout	[optionnel] Vitesse à laquelle la fenêtre doit clignoter, en millisecondes. Si 0, la fonction utilise la fréquence de clignotement du curseur par défaut.