UDF > NetShare >

_Net_Share_ShareDel

Supprime un nom de partage de la liste des ressources partagées d'un serveur

#include <NetShare.au3>
_Net_Share_ShareDel ( $sServer, $sShare )

Paramètres

$sServer Indique le nom DNS ou NetBIOS du serveur distant sur lequel la fonction s'exécutera.
Si ce paramètre est vide, l'ordinateur local est utilisé.
$sShare Indique le nom du partage à supprimer

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Seuls les membres dAdministrateurs, Opérateurs de serveur ou Utilisateurs avec pouvoir groupe local, ou ceux appartenant à un groupe d'opérateur de serveur, peuvent réussir à supprimer les partages de fichiers avec cette fonction.
Un Opérateur d'Impression peut supprimer des partages d'imprimante.

En relation

_Net_Share_SessionDel, _Net_Share_ShareAdd, _Net_Share_ShareCheck

Voir aussi

Consultez NetShareDel dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

#RequireAdmin ; nécessaire pour _Net_Share_ShareAdd()

Global $g_idMemo

Example()

Func Example()
    Local $iI, $aInfo
    Local Const $sShareName = "AutoIt Share"

    ; Crée une GUI
    GUICreate("NetShare", 400, 300)

    ; Crée un contrôle Memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Teste si le partage existe
    If _Net_Share_ShareCheck(@ComputerName, $sShareName) = -1 Then
        ; Crée un partage sur l'ordinateur local
        _Net_Share_ShareAdd(@ComputerName, $sShareName, 0, "C:\", "AutoIt Share Comment")
        If @error Then MsgBox($MB_SYSTEMMODAL, "Information", "Erreur dans ShareAdd: " & @error)
        MemoWrite("Partage ajouté")
    Else
        MemoWrite("Le partage existe")
    EndIf

    ; Affiche des informations sur tous les partages locaux
    $aInfo = _Net_Share_ShareEnum(@ComputerName)
    MemoWrite("Entries read ............: " & $aInfo[0][0])
    For $iI = 1 To $aInfo[0][0]
        MemoWrite("Share name ..............: " & $aInfo[$iI][0])
        MemoWrite("Share type...............: " & _Net_Share_ResourceStr($aInfo[$iI][1]))
        MemoWrite("Comment .................: " & $aInfo[$iI][2])
        MemoWrite("Permissions .............: " & _Net_Share_PermStr($aInfo[$iI][3]))
        MemoWrite("Maximum connections .....: " & $aInfo[$iI][4])
        MemoWrite("Current connections .....: " & $aInfo[$iI][5])
        MemoWrite("Local path ..............: " & $aInfo[$iI][6])
        MemoWrite("Password ................: " & $aInfo[$iI][7])
        MemoWrite()
    Next

    ; Supprime le partage
    _Net_Share_ShareDel(@ComputerName, $sShareName)
    If @error Then MsgBox($MB_SYSTEMMODAL, "Information", "Erreur de suppression du partage: " & @error)
    MemoWrite("Partage supprimé")

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contrôle Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite