Fonction _Net_Share

#include <NetShare.au3>
_Net_Share_ShareAdd ( $sServer, $sShare, $iType, $sResourcePath [, $sComment = "" [, $iMaxUses = -1]] )

Paramètres

Valeur de retour

Remarque

Seuls les membres du groupe local Administrateurs, Gestionnaires de réseau, ou Utilisateurs peuvent ajouter des partages de fichier avec un appel à cette fonction.
L'opérateur d'impression peut ajouter des partages d'imprimantes.

En relation

Voir aussi

Exemple

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

#RequireAdmin : nécessaire pour _Net_Share_ShareAdd()

Global $g_idMemo

Example()

Func Example()
    Local $iI, $aInfo
    Local Const $sShareName = "AutoIt Share"

    ; Crée une GUI
    GUICreate("NetShare", 400, 300)

    ; Crée un contrôle Memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Teste si le partage existe
    If _Net_Share_ShareCheck(@ComputerName, $sShareName) = -1 Then
        ; Crée un partage sur l'ordinateur local
        _Net_Share_ShareAdd(@ComputerName, $sShareName, 0, "C:\", "AutoIt Share Comment")
        If @error Then MsgBox($MB_SYSTEMMODAL, "Information", "Erreur dans ShareAdd: " & @error)
        MemoWrite("Partage ajouté")
    Else
        MemoWrite("Le partage existe")
    EndIf

    ; Affiche des informations sur tous les partages locaux
    $aInfo = _Net_Share_ShareEnum(@ComputerName)
    MemoWrite("Entries read ............: " & $aInfo[0][0])
    For $iI = 1 To $aInfo[0][0]
        MemoWrite("Share name ..............: " & $aInfo[$iI][0])
        MemoWrite("Share type...............: " & _Net_Share_ResourceStr($aInfo[$iI][1]))
        MemoWrite("Comment .................: " & $aInfo[$iI][2])
        MemoWrite("Permissions .............: " & _Net_Share_PermStr($aInfo[$iI][3]))
        MemoWrite("Maximum connections .....: " & $aInfo[$iI][4])
        MemoWrite("Current connections .....: " & $aInfo[$iI][5])
        MemoWrite("Local path ..............: " & $aInfo[$iI][6])
        MemoWrite("Password ................: " & $aInfo[$iI][7])
        MemoWrite()
    Next

    ; Supprime le partage
    _Net_Share_ShareDel(@ComputerName, $sShareName)
    If @error Then MsgBox($MB_SYSTEMMODAL, "Information", "Erreur de suppression du partage: " & @error)
    MemoWrite("Partage supprimé")

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contrôle Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

Succès:	Retourne True.
Échec:	Retourne False.

$sServer	Indique le nom DNS ou NetBIOS du serveur distant sur lequel la fonction s'exécutera. Si ce paramètre est vide, l'ordinateur local est utilisé.
$sShare	Nom de partage d'une ressource
$iType	Type de la ressource partagée. Doit être une combinaison de: $STYPE_DISKTREE - Lecteur de disque $STYPE_PRINTQ - File d'attente d'impression $STYPE_DEVICE - Périphérique de communication $STYPE_IPC - IPC $STYPE_SPECIAL - Partage spécifique réservée aux IPC$ ou l'administration à distance du serveur $STYPE_TEMPORARY - Un partage temporaire
$sResourcePath	Chemin local de la ressource partagée. Pour les disques, c'est le chemin partagée. Pour les files d'impression, c'est le nom de la file d'attente d'impression partagée.
$sComment	[optionnel] Chaîne qui contient un commentaire sur la ressource partagée
$iMaxUses	[optionnel] Nombre maximal de connexions simultanées que la ressource partagée peut accueillir. Le nombre de connexions est illimité si la valeur spécifiée est -1.