UDF > NetShare >


_Net_Share_ResourceStr

Obtient la représentation chaîne d'une ressource

#include <NetShare.au3>
_Net_Share_ResourceStr ( $iResource )

Paramètre

$iResource Type de ressource. Doit être une combinaison de:
    $STYPE_DISKTREE - Lecteur de disque
    $STYPE_PRINTQ - File d'attente d'impression
    $STYPE_DEVICE - Périphérique de communication
    $STYPE_IPC - IPC
    $STYPE_SPECIAL - Partage spécifique réservée au IPC$ ou à l'administration à distance des serveurs
    $STYPE_TEMPORARY - Partage temporaire

Valeur de retour

Retourne une chaîne de type ressource.

Exemple

#include <GUIConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $sServer, $sShare, $aInfo

    ; Crée une GUI
    GUICreate("NetShare", 400, 300)

    ; Crée un contrôle Memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Obtient le serveur et le nom de partage
    $sServer = InputBox("NetWork Demo", "Entrez le nom du serveur:", "\\MyServer", "", 200, 130)
    If @error Then Exit

    $sShare = InputBox("NetWork Demo", "Entrez le nom de partage:", "MyShare", "", 200, 130)
    If @error Then Exit

    ; Énumère les connexions réseau
    $aInfo = _Net_Share_ConnectionEnum($sServer, $sShare)
    MemoWrite("Error ...................: " & @error)
    MemoWrite("Entries read ............: " & $aInfo[0][0])
    For $iI = 1 To $aInfo[0][0]
        MemoWrite("Connection ID ...........: " & $aInfo[$iI][0])
        MemoWrite("Connection type..........: " & _Net_Share_ResourceStr($aInfo[$iI][1]))
        MemoWrite("Number of files open ....: " & $aInfo[$iI][2])
        MemoWrite("Number of users .........: " & $aInfo[$iI][3])
        MemoWrite("Connection time .........: " & $aInfo[$iI][4])
        MemoWrite("Username ................: " & $aInfo[$iI][5])
        MemoWrite("Network name ............: " & $aInfo[$iI][6])
        MemoWrite()
    Next

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contrôle Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite