UDF > GUI > GuiToolbar >

_GUICtrlToolbar_SetToolTips

Définit un contrôle info-bulle associé à un contrôle barre d'outils

#include <GuiToolbar.au3>
_GUICtrlToolbar_SetToolTips ( $hWnd, $hToolTip )

Paramètres

$hWnd Handle du contrôle barre d'outils
$hToolTip Handle du contrôle info-bulle

Valeur de retour

Aucune.

Remarque

Tous les boutons qui sont ajoutés au contrôle avant l'appel de cette fonction ne seront pas enregistrés dans le contrôle info-bulle.

En relation

_GUICtrlToolbar_GetToolTips

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <GuiToolTip.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp

Example()

Func Example()
    Local $hGUI, $hToolbar, $hToolTip

    ; Crée une GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Crée un contrôle ToolTip
    $hToolTip = _GUIToolTip_Create($hToolbar)
    _GUICtrlToolbar_SetToolTips($hToolbar, $hToolTip)

    ; Ajoute des bitmaps système standards
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idHelp, $STD_HELP)

    ; Affiche le handle du ToolTip
    MsgBox($MB_SYSTEMMODAL, "Information", "ToolTip handle .: 0x" & Hex(_GUICtrlToolbar_GetToolTips($hToolbar)))

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Gestionnaire des messages WM_NOTIFY
Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $tInfo, $iID, $iCode

    $tInfo = DllStructCreate($tagNMTTDISPINFO, $lParam)
    $iCode = DllStructGetData($tInfo, "Code")
    If $iCode = $TTN_GETDISPINFOW Then
        $iID = DllStructGetData($tInfo, "IDFrom")
        Switch $iID
            Case $e_idNew
                DllStructSetData($tInfo, "aText", "New")
            Case $e_idOpen
                DllStructSetData($tInfo, "aText", "Open")
            Case $e_idSave
                DllStructSetData($tInfo, "aText", "Save")
            Case $e_idHelp
                DllStructSetData($tInfo, "aText", "Help")
        EndSwitch
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY