UDF > GUI > GuiToolbar >

_GUICtrlToolbar_SetRows

Définit le nombre de rangées de boutons

#include <GuiToolbar.au3>
_GUICtrlToolbar_SetRows ( $hWnd, $iRows [, $bLarger = True] )

Paramètres

$hWnd Handle du contrôle barre d'outils
$iRows Nombre de rangées souhaitées. Le nombre minimum de rangées est un, et le nombre maximum de rangées est égal au nombre total de boutons.
$bLarger [optionnel] Flag qui indique s'il faut créer plus de rangées que le nombre requis lorsque le système ne peut pas créer le nombre de rangées spécifiées par $iRows.
Si ce paramètre est True, le système crée plusieurs rangées.
S'il est False, le système crée moins de rangées.

Valeur de retour

Retourne un tableau avec le format suivant:
    [0] - Coordonnée X du coin supérieur gauche du rectangle
    [1] - Coordonnée Y du coin supérieur gauche du rectangle,
    [2] - Coordonnée X du coin inférieur droit du rectangle
    [3] - Coordonnée Y du coin inférieur droit du rectangle

Remarque

Parce que le système ne coupe pas les groupes de boutons lors de la définition du nombre de rangées, le nombre de rangées qui en résulte peut différer du nombre demandé.

En relation

_GUICtrlToolbar_GetRows

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hToolbar
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Crée une GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $g_idMemo = GUICtrlCreateEdit("", 36, 2, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des bitmaps système standards
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Crée une barre d'outils verticale
    _GUICtrlToolbar_SetStyle($hToolbar, BitOR($CCS_LEFT, $TBSTYLE_FLAT))
    _GUICtrlToolbar_SetRows($hToolbar, 4)

    ; Affiche le nombre de rangées de boutons
    MemoWrite("Number of rows:" & _GUICtrlToolbar_GetRows($hToolbar))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite