UDF > GUI > GuiToolbar >

_GUICtrlToolbar_SetPadding

Définit le rembourrage d'un contrôle barre d'outils

#include <GuiToolbar.au3>
_GUICtrlToolbar_SetPadding ( $hWnd, $iCX, $iCY )

Paramètres

$hWnd Handle du contrôle barre d'outils
$iCX Le rembourrage horizontal, en pixels
$iCY Le rembourrage vertical, en pixels

Valeur de retour

Retourne le rembourrage horizontal précédent dans le mot de poids faible et le rembourrage vertical précédente dans le mot de poids fort.

Remarque

Les valeurs de rembourrage sont utilisées pour créer un espace vide entre le bord d'un bouton et l'image du bouton et/ou du texte.
La valeur de rembourrage horizontal est appliquée à la fois à droite et à gauche d'un bouton et la valeur de rembourrage vertical est appliquée à la fois en haut et en bas d'un bouton.
Le rembourrage est appliqué uniquement aux boutons qui ont le style $BTNS_AUTOSIZE.

En relation

_GUICtrlToolbar_GetPadding

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hToolbar, $aPad
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Crée une GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des bitmaps système standards
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Définit le padding du contrôle
    _GUICtrlToolbar_SetPadding($hToolbar, 2, 3)

    ; Affiche le padding du contrôle
    $aPad = _GUICtrlToolbar_GetPadding($hToolbar)
    MemoWrite("Horizontal padding : " & $aPad[0])
    MemoWrite("Vertical padding ..: " & $aPad[1])
    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite