UDF > GUI > GuiToolbar >

_GUICtrlToolbar_SetButtonState

Définit des informations sur l'état d'un bouton spécifié

#include <GuiToolbar.au3>
_GUICtrlToolbar_SetButtonState ( $hWnd, $iCommandID, $iState )

Paramètres

$hWnd Handle du contrôle barre d'outils
$iCommandID ID de commande du bouton
$iState État du bouton. Peut être l'un ou plusieurs des éléments suivants:
    $TBSTATE_CHECKED - Le bouton a le style $TBSTYLE_CHECK et est en train d'être cliqué
    $TBSTATE_PRESSED - Le bouton est cliqué
    $TBSTATE_ENABLED - Le bouton accepte l'entrée utilisateur
    $TBSTATE_HIDDEN - Le bouton n'est pas visible et ne peut pas recevoir une entrée utilisateur
    $TBSTATE_INDETERMINATE - Le bouton est grisé
    $TBSTATE_WRAP - Le bouton est suivi par un saut de ligne
    $TBSTATE_ELLIPSES - Le texte du bouton est coupée et une ellipse est affiché
    $TBSTATE_MARKED - Le bouton est marqué

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlToolbar_GetButtonState

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hToolbar
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Crée une GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des bitmaps système standards
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Affiche l'état du bouton Save
    MemoWrite("Etat du bouton Save: " & _GUICtrlToolbar_GetButtonState($hToolbar, $e_idSave))

    Sleep(1000)

    ; Définit l'état du bouton Save
    Local $idBalloon = _GUICtrlToolbar_SetButtonState($hToolbar, $e_idSave, BitOR($TBSTATE_ENABLED, $TBSTATE_PRESSED))
    MemoWrite("Définit l'état du bouton: " & $idBalloon)

    ; Affiche l'état du bouton Save
    MemoWrite("Etat du bouton Save: " & _GUICtrlToolbar_GetButtonState($hToolbar, $e_idSave))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite