UDF > GUI > GuiToolbar >

_GUICtrlToolbar_GetStyle

Obtient les styles en cours d'utilisation dans un contrôle barre d'outils

#include <GuiToolbar.au3>
_GUICtrlToolbar_GetStyle ( $hWnd )

Paramètre

$hWnd Handle du contrôle barre d'outils

Valeur de retour

Retourne les styles du contrôle. Peut être une combinaison des éléments suivants:
    $TBSTYLE_TOOLTIPS - Crée un contrôle info-bulle
    $TBSTYLE_WRAPABLE - Crée une barre d'outils qui peut avoir de multiples rangées de boutons
    $TBSTYLE_ALTDRAG - Permet aux utilisateurs de modifier la position d'un bouton de la barre d'outils en le faisant glisser
    $TBSTYLE_FLAT - Crée une barre d'outils sans relief
    $TBSTYLE_LIST - Crée une barre d'outils sans relief avec le texte du bouton à droite du bitmap
    $TBSTYLE_CUSTOMERASE - Envoie des messages $NM_CUSTOMDRAW lors du traitement des messages $WM_ERASEBKGND
    $TBSTYLE_REGISTERDROP - Envoie des messages $TBN_GETOBJECT pour demander la cible des objets glissés
    $TBSTYLE_TRANSPARENT - Crée une barre d'outils transparente

En relation

_GUICtrlToolbar_SetStyle

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hToolbar
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Crée une GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Définit le style du contrôle
    _GUICtrlToolbar_SetStyle($hToolbar, BitOR($TBSTYLE_LIST, $CCS_TOP))

    ; Ajoute des bitmaps système standards
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Affiche le style du contrôle
    MemoWrite("Toolbar style .: 0x" & Hex(_GUICtrlToolbar_GetStyle($hToolbar)))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite