UDF > GUI > GuiToolbar >

_GUICtrlToolbar_GetMetrics

Obtient les mesures d'un contrôle de barre d'outils

#include <GuiToolbar.au3>
_GUICtrlToolbar_GetMetrics ( $hWnd )

Paramètre

$hWnd Handle du contrôle barre d'outils

Valeur de retour

Retourne un tableau avec le format suivant:
    [0] - Largeur du rembourrage à l'intérieur des boutons de la barre d'outils
    [1] - Hauteur du rembourrage à l'intérieur des boutons de la barre d'outils
    [2] - Largeur de l'espace entre les boutons de la barre d'outils
    [3] - Hauteur de l'espace entre les boutons de la barre d'outils

En relation

_GUICtrlToolbar_SetMetrics

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hToolbar, $aMetrics
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Crée une GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des bitmaps système standards
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    MemoWrite("Before _GUICtrlToolbar_SetMetrics")

    Sleep(1000)
    GUISetState(@SW_LOCK)
    ; Définit les mesures du contrôle
    MemoWrite("Step 1:")
    MemoWrite("$iXPad = 10")
    _GUICtrlToolbar_SetMetrics($hToolbar, 10, 0, 0, 0)
    GUISetState(@SW_UNLOCK)

    Sleep(1000)
    GUISetState(@SW_LOCK)
    ; Définit les mesures du contrôle
    MemoWrite("Step 2:")
    MemoWrite("$iYPad = 10")
    _GUICtrlToolbar_SetMetrics($hToolbar, 0, 10, 0, 0)
    GUISetState(@SW_UNLOCK)

    Sleep(1000)
    GUISetState(@SW_LOCK)
    ; Définit les mesures du contrôle
    MemoWrite("Step 3:")
    MemoWrite("$iXSpacing = 10")
    _GUICtrlToolbar_SetMetrics($hToolbar, 0, 0, 10, 0)
    GUISetState(@SW_UNLOCK)

    Sleep(1000)
    GUISetState(@SW_LOCK)
    ; Définit les mesures du contrôle
    MemoWrite("Step 4:")
    MemoWrite("$iYSpacing = 10")
    _GUICtrlToolbar_SetMetrics($hToolbar, 0, 0, 0, 10)
    GUISetState(@SW_UNLOCK)

    Sleep(1000)
    GUISetState(@SW_LOCK)
    ; Définit les mesures du contrôle
    MemoWrite("")
    MemoWrite("Step 5:")
    MemoWrite("$iXPad = 10")
    MemoWrite("$iYPad = 10")
    MemoWrite("$iXSpacing = 10")
    MemoWrite("$iYSpacing = 10")
    _GUICtrlToolbar_SetMetrics($hToolbar, 10, 10, 10, 10)
    GUISetState(@SW_UNLOCK)

    ; Affiche les mesures du contrôle
    $aMetrics = _GUICtrlToolbar_GetMetrics($hToolbar)
    MemoWrite("Button padding width ...: " & $aMetrics[0])
    MemoWrite("Button padding height ..: " & $aMetrics[1])
    MemoWrite("Button spacing width ...: " & $aMetrics[2])
    MemoWrite("Button spacing height ..: " & $aMetrics[3])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite