UDF > GUI > GuiToolbar >

_GUICtrlToolbar_GetButtonInfo

Obtient les informations d'un bouton

#include <GuiToolbar.au3>
_GUICtrlToolbar_GetButtonInfo ( $hWnd, $iCommandID )

Paramètres

$hWnd Handle du contrôle barre d'outils
$iCommandID ID de commande du bouton

Valeur de retour

Retourne un tableau avec le format suivant:
    [0] - Index, de base 0, de l'image du bouton

    [1] - Etat du bouton. Peut être une combinaison des éléments suivants:
        $TBSTATE_CHECKED - Le bouton a été cliqué
        $TBSTATE_PRESSED - Le bouton est en train d'être cliqué
        $TBSTATE_ENABLED - Le bouton accepte l'entrée utilisateur
        $TBSTATE_HIDDEN - Le bouton n'est pas visible
        $TBSTATE_INDETERMINATE - Le bouton est grisé
        $TBSTATE_WRAP - Le bouton est suivie par un saut de ligne
        $TBSTATE_ELLIPSES - Le texte du bouton est coupée
        $TBSTATE_MARKED - Le bouton est marqué

    [2] - Style du bouton. Peut être une combinaison des éléments suivants:
        $BTNS_AUTOSIZE - Le contrôle ne doit pas attribuer la largeur standard
        $BTNS_BUTTON - Le bouton est standard
        $BTNS_CHECK - Bascule entre pressé et non pressé
        $BTNS_CHECKGROUP - Bouton qui reste enfoncé jusqu'à ce qu'un autre bouton soit pressé
        $BTNS_DROPDOWN - Crée un bouton de style déroulante qui permet d'afficher une liste
        $BTNS_GROUP - Bouton qui reste enfoncé jusqu'à ce qu'un autre bouton soit pressé
        $BTNS_NOPREFIX - Le texte du bouton n'aura pas un préfixe d'accélérateur
        $BTNS_SEP - Crée un séparateur
        $BTNS_SHOWTEXT - Indique que le texte du bouton doit être affiché
        $BTNS_WHOLEDROPDOWN - Indique que le bouton aura une flèche déroulante

    [3] - Largeur du bouton

    [4] - Paramètre du bouton

En relation

_GUICtrlToolbar_SetButtonInfo

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hToolbar, $aButton
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Crée une GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des bitmaps système standards
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Définit les informations du bouton Save
    _GUICtrlToolbar_SetButtonInfo($hToolbar, $e_idSave, $STD_PRINT, BitOR($TBSTATE_PRESSED, $TBSTATE_ENABLED), -1, 100, 1234)

    ; Affiche les informations du bouton Save
    $aButton = _GUICtrlToolbar_GetButtonInfo($hToolbar, $e_idSave)
    MemoWrite("Image index ....: " & $aButton[0])
    MemoWrite("State flags ....: " & $aButton[1])
    MemoWrite("Style flags ....: " & $aButton[2])
    MemoWrite("Button width ...: " & $aButton[3])
    MemoWrite("Param ..........: " & $aButton[4])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contrôle memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite