UDF > GUI > GuiSlider >

_GUICtrlSlider_SetTipSide

Définit la position du contrôle ToolTip par rapport au Slider

#include <GuiSlider.au3>
_GUICtrlSlider_SetTipSide ( $hWnd, $iLocation )

Paramètres

$hWnd ID/handle du contrôle Slider
$iLocation Le coté où afficher le contrôle info-bulle. Cette valeur peut être l'un des suivantes:
    $TBTS_TOP - sera positionné au-dessus du Slider. Cet indicateur est utilisé avec les sliders horizontaux.
    $TBTS_LEFT - sera positionné à gauche du Slider. Cet indicateur est utilisé avec les sliders verticaux.
    $TBTS_BOTTOM - sera placé au-dessous du Slider. Cet indicateur est utilisé avec les sliders horizontaux.
    $TBTS_RIGHT - sera placé à la droite du curseur. Cet indicateur est utilisé avec les sliders verticaux.

Valeur de retour

Retourne emplacement précédent du contrôle d'info-bulle.
    La valeur de retour est égale à une des valeurs possibles de $iLocation.

Remarque

Utilisez le style $TBS_TOOLTIPS pour afficher des info-bulles.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiSlider.au3>

Example()

Func Example()
    Local $idRdoBottom, $idRdoLeft, $idRdoRight, $idRdoTop, $idSlider, $idSlider2

    ; Crée une GUI
    GUICreate("Slider Set Tip Side", 400, 296)
    $idSlider = GUICtrlCreateSlider(2, 2, 375, 20, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))
    $idSlider2 = GUICtrlCreateSlider(380, 2, 20, 292, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS, $TBS_VERT))
    GUISetState(@SW_SHOW)

    GUICtrlCreateGroup("Tip Side Horiz", 2, 25, 120, 120)
    $idRdoBottom = GUICtrlCreateRadio("Bottom", 5, 40, 108, 20)
    $idRdoTop = GUICtrlCreateRadio("Top", 5, 115, 108, 20)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
    GUICtrlSetState($idRdoTop, $GUI_CHECKED)

    GUICtrlCreateGroup("Tip Side Vert", 130, 25, 120, 120)
    $idRdoLeft = GUICtrlCreateRadio("Left", 132, 65, 108, 20)
    $idRdoRight = GUICtrlCreateRadio("Right", 132, 90, 108, 20)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
    GUICtrlSetState($idRdoLeft, $GUI_CHECKED)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Local $iMsg
    Do
        $iMsg = GUIGetMsg()
        Switch $iMsg
            Case $idRdoBottom
                _GUICtrlSlider_SetTipSide($idSlider, $TBTS_BOTTOM)
            Case $idRdoLeft
                _GUICtrlSlider_SetTipSide($idSlider2, $TBTS_LEFT)
            Case $idRdoRight
                _GUICtrlSlider_SetTipSide($idSlider2, $TBTS_RIGHT)
            Case $idRdoTop
                _GUICtrlSlider_SetTipSide($idSlider, $TBTS_TOP)
        EndSwitch
    Until $iMsg = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example