Functions > GUI > GUICtrlCreate >

GUICtrlCreateSlider

Crée un contrôle Slider pour une GUI.

GUICtrlCreateSlider ( left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

Paramètres

left	Coordonnée X du coin supérieur gauche du contrôle. Si -1 est utilisé, X sera calculée en accord avec GUICoordMode.
top	Coordonnée Y du coin supérieur gauche du contrôle. Si -1 est utilisé, Y sera calculée en accord avec GUICoordMode.
width	[optionnel] Largeur du contrôle (par défaut, la largeur utilisée précédemment).
height	[optionnel] Hauteur du contrôle (par défaut, la hauteur précédemment utilisé).
style	[optionnel] Définit le style du contrôle. Consultez Annexe des styles des contrôles GUI. Par défaut (-1): $TBS_AUTOTICKS
exStyle	[optionnel] Définit les styles étendus du contrôle. Consultez Table des styles étendus.

Valeur de retour

Succès:	Retourne l'ID du nouveau contrôle.
Échec:	Retourne 0.

Remarques

Un contrôle Slider permet aux utilisateurs de sélectionner une valeur dans une plage, en déplaçant un curseur le long d'une ligne graduée.
Exemple d'un contrôle Slider

Pour obtenir la valeur du contrôle, consultez GUICtrlRead().
Pour définir ou modifier des informations dans le contrôle, consultez les fonctions GUICtrlUpdate...().

Pour modifier la position du curseur, utilisez GUICtrlSetData().
Pour définir les valeurs minimun et maximum, utilisez GUICtrlSetLimit().

Pour combiner des styles avec le style par défaut, utilisez BitOR ($GUI_SS_DEFAULT_SLIDER, newstyle, ...).
Pour utiliser les valeurs spécifiées ci-dessus, vous devez ajouter #include <SliderConstants.au3> dans votre script.

Pour redimensionner le contrôle par défaut, utilisez $GUI_DOCKAUTO.

En relation

GUICoordMode (Option), GUICtrlSetData, GUICtrlSetLimit, GUICtrlUpdate..., GUIGetMsg

Exemple

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()

    GUICreate("slider", 220, 100, 100, 200)
    GUISetBkColor(0x00E0FFFF) ; Change la couleur de fond

    Local $idSlider1 = GUICtrlCreateSlider(10, 10, 200, 20)
    GUICtrlSetLimit(-1, 200, 0) ; Change les valeurs min/max
    Local $idButton = GUICtrlCreateButton("Value?", 75, 70, 70, 20)
    GUISetState(@SW_SHOW)
    GUICtrlSetData($idSlider1, 45) ;ensemble curseur

    Local $idMsg
    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
        $idMsg = GUIGetMsg()

        If $idMsg = $idButton Then
            MsgBox($MB_SYSTEMMODAL, "slider1", GUICtrlRead($idSlider1), 2)
        EndIf
    Until $idMsg = $GUI_EVENT_CLOSE
EndFunc   ;==>Example