Functions > GUI > GUICtrlCreate >

GUICtrlCreateRadio

Crée un contrôle RadioButton pour une GUI.

GUICtrlCreateRadio ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

Paramètres

text Le texte du contrôle.
left Coordonnée X du coin supérieur gauche du contrôle. Si -1 est utilisé, X sera calculée en accord avec GUICoordMode.
top Coordonnée Y du coin supérieur gauche du contrôle. Si -1 est utilisé, Y sera calculée en accord avec GUICoordMode.
width [optionnel] Largeur du contrôle (par défaut, ajustement automatique du texte en largeur).
height [optionnel] Hauteur du contrôle (par défaut, ajustement automatique du texte en hauteur).
style [optionnel] Définit le style du contrôle. Consultez Annexe des styles des contrôles GUI.
    Par défaut (-1) : aucun.
    Styles forcés : $BS_AUTORADIOBUTTON et $WS_TABSTOP si premier radio-bouton du groupe.
exStyle [optionnel] Définit le style étendu du contrôle. Consultez Table des styles étendus.

Valeur de retour

Succès: Retourne l'ID du nouveau contrôle.
Échec: Retourne 0.

Remarques

Pour obtenir la valeur du contrôle, consultez GUICtrlRead().
Pour définir ou modifier des informations dans le contrôle, consultez les fonctions GUICtrlUpdate...().

Pour combiner des styles avec les styles par défaut utilisez BitOR ($GUI_SS_DEFAULT_RADIO, newstyle, ...).
Pour utiliser les valeurs spécifiées ci-dessus, vous devez ajouter #include <ButtonConstants.au3> dans votre script.

Par défaut le redimensionnement est $GUI_DOCKHEIGHT.

En relation

GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg

Exemple

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("My GUI radio") ; Crée une GUI centrée

    Local $idRadio1 = GUICtrlCreateRadio("Radio 1", 10, 10, 120, 20)
    Local $idRadio2 = GUICtrlCreateRadio("Radio 2", 10, 40, 120, 20)
    GUICtrlSetState($idRadio2, $GUI_CHECKED)

    GUISetState(@SW_SHOW) ; Affiche une boîte de dialogue avec une case à cocher

    Local $idMsg = GUIGetMsg()
    ; Boucle jusqu'à ce que l'utilisateur quitte.
    While $idMsg <> $GUI_EVENT_CLOSE
        Select
            Case $idMsg = $idRadio1 And BitAND(GUICtrlRead($idRadio1), $GUI_CHECKED) = $GUI_CHECKED
                MsgBox($MB_SYSTEMMODAL, 'Info:', 'Vous avez cliqué sur le bouton Radio1 et il est Checked.')
            Case $idMsg = $idRadio2 And BitAND(GUICtrlRead($idRadio2), $GUI_CHECKED) = $GUI_CHECKED
                MsgBox($MB_SYSTEMMODAL, 'Info:', 'Vous avez cliqué sur le bouton Radio2 et il est Checked.')
        EndSelect
        $idMsg = GUIGetMsg()
    WEnd
EndFunc   ;==>Example