UDF > GUI > GuiRichEdit >


_GUICtrlRichEdit_GetPasswordChar

Obtient le caractère de remplacement que le contrôle RichEdit affiche lorsque l'utilisateur saisit un mot de passe

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetPasswordChar ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Succès: Retourne le caractère qui s'affiche à la place des caractères tapés par l'utilisateur.
0 - il n'y a pas de caractère de mot de passe, le contrôle affiche les caractères tapés par l'utilisateur.
Échec: Retourne une chaîne vide et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle

En relation

_GUICtrlRichEdit_SetPasswordChar

Voir aussi

Consultez EM_GETPASSWORDCHAR dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    Report("Etat initial après création:")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
            $iStep += 1
            Switch $iStep
                Case 1
                    _GUICtrlRichEdit_SetPasswordChar($g_hRichEdit, "*")
                    Report("A changé le caractère mot de passe. Tapez du texte")
                Case 2
                    _GUICtrlRichEdit_SetPasswordChar($g_hRichEdit, "")
                    Report("L'a remis comme il était")
                    GUICtrlSetState($idBtnNext, $GUI_DISABLE)
            EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    Local $sPasswordChar
    $sPasswordChar = _GUICtrlRichEdit_GetPasswordChar($g_hRichEdit)
    If $sPasswordChar = "" Then
        $sMsg &= @CRLF & "Les caractères apparaîssent tel que tapés"
    Else
        $sMsg = $sMsg & @CRLF & "Les caractères sont remplacés par " & $sPasswordChar
    EndIf
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report