UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_GetParaAlignment

Obtient l'alignement du ou des paragraphes sélectionnés, ou (à défaut de sélection) du paragraphe courant

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaAlignment ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Succès: Retourne une chaîne constituée d'une lettre pour l'alignement, d'un point-virgule, et d'une lettre pour la portée :
Alignement :
    l - (left) aligné sur la marge gauche.
    r - (right) aligné sur la marge droite.
    c - (centered) centré entre les marges
    j - (justified) justifié entre les marges
    f - (justified) justifié entre les marges
    w - (justified) justifié entre les marges par seulement des espaces d'expansion
Portée :
    a - (all) tous (ou seulement) les paragraphes sélectionnés ont cet alignement
    f - (first) le premier paragraphe sélectionné a cet alignement, mais d'autres ne l'ont pas
    c - (current) le paragraphe courant a cet alignement
Échec: Retourne "" et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle

Remarque

Dans Richedit 2.0, la justification ne s'affiche pas.

En relation

_GUICtrlRichEdit_SetParaAlignment

Voir aussi

Consultez EM_SETPARAFORMAT dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $iCp, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Suivant", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "Premier paragraphe")
    Report("Premier paragraphe")

    $iMsg = GUIGetMsg()
    While $iMsg <> $GUI_EVENT_CLOSE
        If $iMsg = $idBtnNext Then
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetParaAlignment($g_hRichEdit, "r")
                        Report("Premier paragraphe")
                    Case 2
                        _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraphee")
                        _GUICtrlRichEdit_SetParaAlignment($g_hRichEdit, "c")
                        Report("Second paragraphee")
                    Case 3
                        _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Troisième paragraphe")
                        _GUICtrlRichEdit_SetParaAlignment($g_hRichEdit, "l")
                        Report("Troisième paragraphe")
                    Case 4
                        $iCp = _GUICtrlRichEdit_GetFirstCharPosOnLine($g_hRichEdit, 2)
                        _GUICtrlRichEdit_SetSel($g_hRichEdit, $iCp, -1)
                        Report("Alignement des paragraphes de la sélection")
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndIf
        $iMsg = GUIGetMsg()
    WEnd

    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CRLF & @CRLF & "Obtient le retour de la fonction: " & @CRLF & _GUICtrlRichEdit_GetParaAlignment($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report