UDF > GUI > GuiComboBox >


_GUICtrlComboBox_AddDir

Ajoute des noms de répertoires et de fichiers à la liste déroulante d'une ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_AddDir ( $hWnd, $sFilePath [, $iAttributes = 0 [, $bBrackets = True]] )

Paramètres

$hWnd ID/handle du contrôle
$sFilePath Indique un chemin absolu, un chemin relatif ou un nom de fichier
$iAttributes [optionnel] Spécifie les attributs des fichiers ou des répertoires à ajouter :
    $DDL_READWRITE - Comprend des fichiers en lecture-écriture avec aucun attribut supplémentaire
    $DDL_READONLY - Comprend les fichiers en lecture seule
    $DDL_HIDDEN - Comprend les fichiers cachés
    $DDL_SYSTEM - Comprend les fichiers système
    $DDL_DIRECTORY - Comprend les répertoires
    $DDL_ARCHIVE - Inclut les fichiers archivés
    $DDL_DRIVES - Tous les lecteurs mappés sont ajoutés à la liste
    $DDL_EXCLUSIVE - Comprend uniquement les fichiers avec les attributs spécifiés
$bBrackets [optionnel] Inclut/exclut des crochets quand $DDL_DRIVES est utilisé

Valeur de retour

Succès: Retourne l'index, à partir de 0, du dernier nom ajouté.
Échec: Retourne -1.

Remarques

Si l'espace est insuffisant pour stocker les nouvelles chaînes, la valeur de retour est de $CB_ERRSPACE.

 Les constantes ci-dessus nécessitent #include <DirConstants.au3>

En relation

_GUICtrlComboBox_InitStorage

Exemple

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idCombo

    ; Crée une GUI
    GUICreate("ComboBox Add Dir", 400, 296)
    $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($idCombo)

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example