UDF > GUI > GuiMenu >

_GUICtrlMenu_SetItemType

Définit le type d'un élément de menu

#include <GuiMenu.au3>
_GUICtrlMenu_SetItemType ( $hMenu, $iItem, $iType [, $bByPos = True] )

Paramètres

$hMenu Handle du contrôle Menu
$iItem Identifiant ou position de l'élément de menu
$iType Type de l'élément de menu. Peut prendre une ou plusieurs des valeurs suivantes:
    $MFT_BITMAP - L'élément est affiché en utilisant un bitmap
    $MFT_MENUBARBREAK - L'élément est placé sur une nouvelle ligne. Une ligne verticale sépare la nouvelle colonne de l'ancienne.
    $MFT_MENUBREAK - L'élément est placé sur une nouvelle ligne. Les colonnes ne sont pas séparés par une ligne verticale.
    $MFT_OWNERDRAW - L'élément se redessine lui-même
    $MFT_RADIOCHECK - L'élément est affiché en utilisant une marque de bouton radio
    $MFT_RIGHTJUSTIFY - L'élément est justifié à droite
    $MFT_RIGHTORDER - L'élément est décalé de droite à gauche
    $MFT_SEPARATOR - Le produit est un séparateur
$bByPos [optionnel] Indicateur d'identifiant de menu:
    True  - $iItem est une position de base 0 de l'élément
    False - $iItem est un identifiant d'élément de menu

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlMenu_GetItemType

Exemple

#include <GuiMenu.au3>

Example()

Func Example()
    Local $hWnd, $hMain, $hFile

    ; Ouvre le Bloc-Notes
    Run("notepad.exe")
    WinWaitActive("[CLASS:Notepad]")
    $hWnd = WinGetHandle("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)
    $hFile = _GUICtrlMenu_GetItemSubMenu($hMain, 0)

    ; Change le type de l'élément Open
    Writeln("Type de l'élément Open: 0x" & Hex(_GUICtrlMenu_GetItemType($hFile, 1)))
    _GUICtrlMenu_SetItemType($hFile, 1, $MFT_RADIOCHECK)
    _GUICtrlMenu_CheckRadioItem($hFile, 0, 8, 1)
    Writeln("Type de l'élément Open: 0x" & Hex(_GUICtrlMenu_GetItemType($hFile, 1)))
EndFunc   ;==>Example

; Ecrit une ligne de texte dans le Bloc-Notes
Func Writeln($sText)
    ControlSend("[CLASS:Notepad]", "", "Edit1", $sText & @CRLF)
EndFunc   ;==>Writeln