Functions > Window >


WinGetHandle

Obtient le handle interne d'une fenêtre.

WinGetHandle ( "title" [, "text"] )

Paramètres

title Le titre/hWnd/class de la fenêtre à traiter. Consultez Définition spéciale de titre.
text [optionnel] Le texte de la fenêtre à traiter. La valeur par défaut est une chaîne vide. Consultez Définition spéciale de texte.

Valeur de retour

Succès: Retourne le handle de la fenêtre.
Échec: Définit @error <> 0 si la fenêtre n'est pas trouvée.

Remarques

Cette fonction vous permet d'utiliser les handles pour spécifier les fenêtres plutôt que le "titre" et le "texte".
Une fois que vous avez obtenu le handle, vous pouvez accéder à la fenêtre, même si son titre change.

En relation

GUICreate, WinList, WinSetTitle

Exemple

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Exécute le Bloc-notes
    Run("notepad.exe")

    ; Attend 10 secondes pour que la fenêtre du bloc-notes apparaisse.
    WinWait("[CLASS:Notepad]", "", 10)

    ; Récupére le handle de la fenêtre du Bloc-notes à l'aide du nom de classe du Bloc-notes.
    Local $hWnd = WinGetHandle("[CLASS:Notepad]")
    If @error Then
        MsgBox($MB_SYSTEMMODAL, "", "Une erreur est survenue lors de la récupération du handle de la fenêtre Notepad.")
        Exit
    EndIf

    ; Affiche Le handle de la fenêtre du Bloc-notes.
    MsgBox($MB_SYSTEMMODAL, "", $hWnd)

    ; Ferme la fenêtre du Bloc-notes en utilisant le handle retourné par WinGetHandle.
    WinClose($hWnd)
EndFunc   ;==>Example