UDF > GUI > GuiMenu >

_GUICtrlMenu_CheckRadioItem

Coche un élément de menu spécifié et en fait un élément radio

#include <GuiMenu.au3>
_GUICtrlMenu_CheckRadioItem ( $hMenu, $iFirst, $iLast, $iCheck [, $bByPos = True] )

Paramètres

$hMenu Handle du contrôle Menu
$iFirst Identifiant ou position du premier élément de menu dans le groupe
$iLast Identifiant ou position du dernier élément de menu dans le groupe
$iCheck Identifiant ou position de l'élément de menu à cocher
$bByPos [optionnel] Indicateur des identifiants de Menu:
    True  - $iFirst, $iLast et $iCheck sont des positions de base 0 d'éléments de menu
    False - $iFirst, $iLast et $iCheck sont des identifiants d'éléments de menu

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Cette fonction active l'indicateur $MFT_RADIOCHECK et l'état $MFS_CHECKED pour l'élément spécifié par $iCheck et, en même temps, désactive les indicateurs pour tous les autres éléments du groupe. L'élément coché est affiché en utilisant un bitmap représentant un rond à la place d'un carré.

En relation

_GUICtrlMenu_CheckMenuItem

Voir aussi

Consultez CheckMenuRadioitem dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>

Example()

Func Example()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste, $e_idAbout

    ; Crée une GUI
    $hGUI = GUICreate("Menu", 400, 300)

    ; Crée un menu File
    $hFile = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hFile, 0, "&New", $e_idNew)
    _GUICtrlMenu_InsertMenuItem($hFile, 1, "&Open", $e_idOpen)
    _GUICtrlMenu_InsertMenuItem($hFile, 2, "&Save", $e_idSave)
    _GUICtrlMenu_InsertMenuItem($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem($hFile, 4, "E&xit", $e_idExit)

    ; Crée un menu Edit
    $hEdit = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hEdit, 0, "&Cut", $e_idCut)
    _GUICtrlMenu_InsertMenuItem($hEdit, 1, "C&opy", $e_idCopy)
    _GUICtrlMenu_InsertMenuItem($hEdit, 2, "&Paste", $e_idPaste)

    ; Crée un menu Help
    $hHelp = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hHelp, 0, "&About", $e_idAbout)

    ; Crée un menu Main
    $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hMain, 0, "&File", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem($hMain, 1, "&Edit", 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem($hMain, 2, "&Help", 0, $hHelp)

    ; Attache le menu à la fenêtre
    _GUICtrlMenu_SetMenu($hGUI, $hMain)
    GUISetState(@SW_SHOW)

    ; Coche l'élément Open du menu
    _GUICtrlMenu_CheckRadioItem($hFile, 0, 4, 2)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example