UDF > GUI > GuiMenu >

_GUICtrlMenu_GetMenu

Obtient le handle du menu attaché à la fenêtre donnée

#include <GuiMenu.au3>
_GUICtrlMenu_GetMenu ( $hWnd )

Paramètre

$hWnd Identifie la fenêtre dont le handle du menu est à récupérer

Valeur de retour

Succès: Retourne le handle du menu.
Échec: Retourne 0.

Remarque

_GUICtrlMenu_GetMenu() ne fonctionne pas sur les barres de menus flottantes.
Les barres de menus flottants sont des contrôles personnalisés qui imitent des menus standards, mais ne sont pas des menus.

En relation

_GUICtrlMenu_FindParent, _GUICtrlMenu_SetMenu

Voir aussi

Consultez GetMenu dans la librairie MSDN.

Exemple

#include <GuiMenu.au3>

Example()

Func Example()
    Local $hWnd, $hMain, $hitem1, $hitem2

    ; Ouvre le Bloc-Notes
    Run("notepad.exe")
    WinWaitActive("[CLASS:Notepad]")
    $hWnd = WinGetHandle("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)

    ; Crée un sous-menu
    $hitem1 = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hitem1, 0, "Subitem &1", 0x1000)
    _GUICtrlMenu_InsertMenuItem($hitem1, 1, "Subitem &2", 0x1001)

    ; Crée un menu
    $hitem2 = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hitem2, 0, "item &1", 0x2000, $hitem1)
    _GUICtrlMenu_InsertMenuItem($hitem2, 1, "item &2", 0x2001)
    _GUICtrlMenu_InsertMenuItem($hitem2, 2, "", 0)
    _GUICtrlMenu_InsertMenuItem($hitem2, 3, "item &3", 0x2002)
    _GUICtrlMenu_InsertMenuItem($hitem2, 4, "item &4", 0x2003)

    ; Insére le nouveau menu dans le Bloc-Notes
    _GUICtrlMenu_InsertMenuItem($hMain, 6, "&AutoIt", 0, $hitem2)
    _GUICtrlMenu_DrawMenuBar($hWnd)
EndFunc   ;==>Example