UDF > GUI > GuiListView >

_GUICtrlListView_SetItem

Définit quelques-uns ou tous les attributs d'un élément

#include <GuiListView.au3>
_GUICtrlListView_SetItem ( $hWnd, $sText [, $iIndex = 0 [, $iSubItem = 0 [, $iImage = -1 [, $iParam = -1 [, $iIndent = -1]]]]] )

Paramètres

$hWnd ID/handle du contrôle
$sText Texte de l'élément. Voir Remarque.
$iIndex [optionnel] Index de l'élément, de base 0
$iSubItem [optionnel] Index du sous-élément de base 1, ou zéro si cela se réfère à un élément
$iImage [optionnel] Index de base 0 de l'icône de l'élément dans la liste d'images du contrôle
$iParam [optionnel] Valeur spécifique à l'élément
$iIndent [optionnel] Nombre de largeurs d'image pour le retrait de l'élément. Un seul retrait est égal à la largeur d'une image.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarques

Si un rappel de notification est nécessaire, vous devez spécifier $sText = -1 (LPSTR_TEXTCALLBACK).

Comme AutoIt utilise le paramètre $iParam pour stocker le controlID des éléments de la ListView créés de façon native, cette valeur doit être suffisamment élevée pour les éléments créés avec l'UDF afin d'éviter tout conflit avec des contrôles existants - une valeur de départ de 1000 est recommandé.

En relation

_GUICtrlListView_GetItem, _GUICtrlListView_SetItemEx

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListview

    GUICreate("ListView Set Item", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Ajoute des éléments
    GUICtrlCreateListViewItem("Item 1", $idListview)
    GUICtrlCreateListViewItem("Item 2", $idListview)
    GUICtrlCreateListViewItem("Item 3", $idListview)

    ; Modifie l'élément 2
    MsgBox($MB_SYSTEMMODAL, "Information", "Changing item 2")
    _GUICtrlListView_SetItem($idListview, "New Item 2", 1)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example