UDF > GUI > GuiListView >

_GUICtrlListView_GetItemCut

Détermine si un élément est marqué pour une opération de couper-coller

#include <GuiListView.au3>
_GUICtrlListView_GetItemCut ( $hWnd, $iIndex )

Paramètres

$hWnd ID/handle du contrôle
$iIndex Index de l'élément, de base 0

Valeur de retour

True: L'élément est marqué pour une opération de couper-coller.
False: L'élément n'est pas marqué pour une opération de couper-coller.

En relation

_GUICtrlListView_SetItemCut

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListview

    GUICreate("ListView Get Item Cut", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 2: Col 2", 1)
    _GUICtrlListView_AddItem($idListview, "Row 3: Col 1", 2)

    ; Coupe l'item 2
    _GUICtrlListView_SetItemCut($idListview, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", "Item 2 Cut: " & _GUICtrlListView_GetItemCut($idListview, 1))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    
    GUIDelete()
EndFunc   ;==>Example