UDF > GUI > GuiListBox >

_GUICtrlListBox_SetCaretIndex

Définit le rectangle focus sur l'élément d'index spécifié dans une ListBox à sélection multiple

#include <GuiListBox.au3>
_GUICtrlListBox_SetCaretIndex ( $hWnd, $iIndex [, $bPartial = False] )

Paramètres

$hWnd ID/handle du contrôle
$iIndex Index de l'élément, compté à partir de 0
$bPartial [optionnel] Si False, l'élément défile jusqu'à ce qu'il soit entièrement visible.
Si True, l'élément défile jusqu'à ce qu'il soit au moins partiellement visible.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlListBox_GetCaretIndex

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>

Example()

Func Example()
    Local $iIndex, $idListBox

    ; Crée une GUI
    GUICreate("List Box Set Caret Index", 400, 296)
    $idListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Ajoute des chaînes
    _GUICtrlListBox_BeginUpdate($idListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($idListBox)

    ; Définit l'index du curseur
    _GUICtrlListBox_SetCaretIndex($idListBox, 2)

    ; Lit l'index du curseur
    $iIndex = _GUICtrlListBox_GetCaretIndex($idListBox)
    _GUICtrlListBox_SetCurSel($idListBox, $iIndex)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example