UDF > GUI > GuiListBox >

_GUICtrlListBox_SetCurSel

Sélectionne une chaîne et la fait défiler pour qu'elle soit visible, si nécessaire

#include <GuiListBox.au3>
_GUICtrlListBox_SetCurSel ( $hWnd, $iIndex )

Paramètres

$hWnd ID/handle du contrôle
$iIndex Index de la chaîne à sélectionner, compté à partir de 0.
Si ce paramètre est -1, la ListBox n'aura aucune sélection.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Utilisez cette fonction seulement avec des ListBox à sélection unique.
Vous ne pouvez pas l'utiliser pour définir ou enlever une sélection dans une ListBox à sélection multiple.

En relation

_GUICtrlListBox_GetCurSel

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListBox

    ; Crée une GUI
    GUICreate("List Box Set Cur Sel", 400, 296)
    $idListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Ajoute des chaînes
    _GUICtrlListBox_BeginUpdate($idListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($idListBox)

    ; Sélectionne un élément
    _GUICtrlListBox_SetCurSel($idListBox, 4)

    ; Obtient l'élément sélectionné en cours
    MsgBox($MB_SYSTEMMODAL, "Information", "Current selction: " & _GUICtrlListBox_GetCurSel($idListBox))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example