UDF > GUI > GuiListBox >

_GUICtrlListBox_GetCaretIndex

Retourne l'index de l'élément qui a le focus sur son rectangle

#include <GuiListBox.au3>
_GUICtrlListBox_GetCaretIndex ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Succès: Retourne l'index de l'élément sélectionné, compté à partir de 0.
Échec: Retourne -1 si rien n'est sélectionné.

En relation

_GUICtrlListBox_SetCaretIndex

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>

Example()

Func Example()
    Local $iIndex, $idListBox

    ; Crée une GUI
    GUICreate("List Box Get Caret Index", 400, 296)
    $idListBox = GUICtrlCreateList("", 2, 2, 396, 296)

    GUISetState(@SW_SHOW)

    ; Ajoute des chaînes
    _GUICtrlListBox_BeginUpdate($idListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($idListBox)

    ; Définit l'index du curseur
    _GUICtrlListBox_SetCaretIndex($idListBox, 2)

    ; Lit l'index du curseur
    $iIndex = _GUICtrlListBox_GetCaretIndex($idListBox)
    _GUICtrlListBox_SetCurSel($idListBox, $iIndex)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example