UDF > GUI > GuiListBox >

_GUICtrlListBox_FindInText

Recherche un élément qui contient le texte spécifié n'importe où dans son texte

#include <GuiListBox.au3>
_GUICtrlListBox_FindInText ( $hWnd, $sText [, $iStart = -1 [, $bWrapOK = True]] )

Paramètres

$hWnd ID/handle du contrôle
$sText Texte dont il faut chercher une correspondance
$iStart [optionnel] Index de l'élément, compté à partir de 0, sur lequel commence la recherche ou -1 pour commencer au début.
L'élément spécifié est lui-même exclu de la recherche.
$bWrapOK [optionnel] Si True, la recherche se poursuivra avec le premier élément si aucune correspondance n'est trouvée

Valeur de retour

Succès: Retourne l'index de l'élément, compté à partir de 0.
Échec: Retourne -1.

Remarque

La recherche est insensible à la casse.

En relation

_GUICtrlListBox_FindString, _GUICtrlListBox_SelectString

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>

Example()

Func Example()
    Local $iIndex, $idListBox

    ; Crée une GUI
    GUICreate("List Box Find In Text", 400, 296)
    $idListBox = GUICtrlCreateList("", 2, 2, 396, 296)

    GUISetState(@SW_SHOW)

    ; Ajoute des chaînes
    _GUICtrlListBox_BeginUpdate($idListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_InsertString($idListBox, "eXaCt tExT", 3)
    _GUICtrlListBox_EndUpdate($idListBox)

    ; Cherche un élément
    $iIndex = _GUICtrlListBox_FindInText($idListBox, "exa")
    _GUICtrlListBox_SetCurSel($idListBox, $iIndex)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example