UDF > GUI > GuiListBox >

_GUICtrlListBox_SelectString

Recherche un élément qui commence par la chaîne spécifiée

#include <GuiListBox.au3>
_GUICtrlListBox_SelectString ( $hWnd, $sText [, $iIndex = -1] )

Paramètres

$hWnd ID/handle du contrôle
$sText Chaîne à rechercher.
$iIndex [optionnel] Spécifie l'index de l'élément, compté à partir de 0, qui précède le premier élément concerné par la recherche.
Lorsque la recherche atteint la fin de la liste, elle continue à partir du haut de la ListBox pour retourner à l'élément spécifié par $iIndex.
Si $iIndex est égal -1, la liste entière est concerné par la recherche, depuis le début.

Valeur de retour

Succès: Retourne l'index, compté à partir de 0, de l'élément sélectionné.
Échec: Retourne -1.

Remarque

La ListBox défile, si nécessaire, pour faire apparaître l'élément sélectionné dans la vue.
Ne pas utiliser cette fonction avec une ListBox qui a le style $LBS_MULTIPLESEL ou $LBS_EXTENDEDSEL.

En relation

_GUICtrlListBox_FindInText, _GUICtrlListBox_FindString

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $sText, $idListBox

    ; Crée une GUI
    GUICreate("List Box Select String", 400, 296)
    $idListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Ajoute des chaînes
    _GUICtrlListBox_BeginUpdate($idListBox)
    For $iI = 1 To 10
        $sText = StringFormat("%03d : Random string ", Random(1, 100, 1))
        For $iX = 1 To Random(1, 20, 1)
            $sText &= Chr(Random(65, 90, 1))
        Next
        _GUICtrlListBox_AddString($idListBox, $sText)
    Next
    _GUICtrlListBox_AddString($idListBox, "020 : Target string")
    _GUICtrlListBox_EndUpdate($idListBox)

    ; Sélectionne une chaîne
    MsgBox($MB_SYSTEMMODAL, "Information", "Target String Index: " & _GUICtrlListBox_SelectString($idListBox, "020 : T")); 

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example