UDF > GUI > GuiEdit >

_GUICtrlEdit_SetTabStops

Définit les taquets de tabulation

#include <GuiEdit.au3>
_GUICtrlEdit_SetTabStops ( $hWnd, $aTabStops )

Paramètres

$hWnd ID/handle du contrôle
$aTabStops Tableau des taquets de tabulation dans le format suivant:
[0] - Taquet de tabulation 1
[2] - Taquet de tabulation 2
[n] - Taquet de tabulation n

Valeur de retour

Retourne True si tous les taquets sont installés.
Retourne False si tous les onglets ne sont pas installés.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hStatusBar, $idEdit, $hGUI
    Local $aPartRightSide[3] = [190, 378, -1], $aTabStops[3] = [10, 30, 50]

    ; Crée une GUI
    $hGUI = GUICreate("Edit Set Tab Stops", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 2, 97, "shell32.dll")
    GUISetState(@SW_SHOW)

    ; Définit les marges
    _GUICtrlEdit_SetMargins($idEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; Définit le texte
    _GUICtrlEdit_SetText($idEdit, @TAB & "1st" & @TAB & "2nd" & @TAB & "3rd")

    MsgBox($MB_SYSTEMMODAL, "Information", "Set Tab Stops")
    ; Définit les taquets de tabulation
    _GUICtrlEdit_SetTabStops($idEdit, $aTabStops)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example