UDF > GUI > GuiComboBox >

_GUICtrlComboBox_SetExtendedUI

Sélectionne l'interface utilisateur par défaut ou l'interface utilisateur étendue

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetExtendedUI ( $hWnd [, $bExtended = False] )

Paramètres

$hWnd ID/handle du contrôle
$bExtended [optionnel] Indique si la ComboBox utilise l'extension

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarques

Par défaut, la touche F4 ouvre ou ferme la liste et la flèche vers le bas modifie la sélection courante.

Dans une CombpBox avec l'interface utilisateur avancée, la touche F4 est désactivée et appuyer sur la flèche vers le bas ouvre la liste déroulante.

En relation

_GUICtrlComboBox_GetExtendedUI

Exemple

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

Global $g_idMemo

Example()

Func Example()
    Local $idCombo

    ; Crée une GUI
    GUICreate("ComboBox Set Extended UI", 400, 296)
    $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($idCombo)

    ; Obtient l'Extended UI
    MemoWrite("Extended UI: " & _GUICtrlComboBox_GetExtendedUI($idCombo))

    ; Définit l'Extended UI
    _GUICtrlComboBox_SetExtendedUI($idCombo, True)

    ; Obtien l'Extended UI
    MemoWrite("Extended UI: " & _GUICtrlComboBox_GetExtendedUI($idCombo))

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite