UDF > GUI > GuiComboBox >

_GUICtrlComboBox_GetExtendedUI

Détermine si une ComboBox a l'interface utilisateur par défaut ou l'interface utilisateur étendue

#include <GuiComboBox.au3>
_GUICtrlComboBox_GetExtendedUI ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

True: la ComboBox a l'interface utilisateur étendue.
False: la ComboBox n'a PAS l'interface utilisateur étendue.

Remarques

Par défaut, la touche F4 ouvre ou ferme la liste déroulante et la touche DOWN ARROW modifie la sélection courante.

Dans une ComboBox avec l'interface utilisateur étendue, la touche F4 est désactivée et la touche DOWN ARROW ouvre la liste déroulante

En relation

_GUICtrlComboBox_SetExtendedUI

Exemple

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

Global $g_idMemo

Example()

Func Example()
    Local $idCombo

    ; Crée une GUI
    GUICreate("ComboBox Get Extended UI", 400, 296)
    $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($idCombo)

    ; Obtient Extended UI
    MemoWrite("Extended UI: " & _GUICtrlComboBox_GetExtendedUI($idCombo))

    ; Définit Extended UI
    _GUICtrlComboBox_SetExtendedUI($idCombo, True)

    ; Obtient Extended UI
    MemoWrite("Extended UI: " & _GUICtrlComboBox_GetExtendedUI($idCombo))

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle Mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite