UDF > GUI > GuiComboBoxEx >

_GUICtrlComboBoxEx_SetEditSel

Sélectionne des caractères dans le champ de saisie d'une ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetEditSel ( $hWnd, $iStart, $iStop )

Paramètres

$hWnd Handle du contrôle
$iStart Position de départ
$iStop Position de fin

Valeur de retour

Succès: Retourne True.
Échec: Retourne False, si le message est envoyé à une ComboBox qui a le style $CBS_DROPDOWN ou $CBS_DROPDOWNLIST.

Remarques

Les positions sont comptées à partir de 0. Le premier caractère du champ de saisie est en position zéro.
Si $iSTOP vaut -1, tout le texte de la position de départ jusqu'au dernier caractère du champ de saisie est sélectionné.

Le premier caractère suivant le dernier caractère sélectionné est en position de fin.

Par exemple, pour sélectionner les quatre premiers caractères du champ de saisie, utilisez une position de départ de 0 et une position de fin de 4.

En relation

_GUICtrlComboBox_GetEditSel, _GUICtrlComboBoxEx_GetEditSel

Exemple

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hImage, $aSel, $hCombo

    ; Crée une GUI
    $hGUI = GUICreate("ComboBoxEx Set Edit Sel", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 70, BitOR($CBS_SIMPLE, $WS_VSCROLL, $WS_BORDER))
    $g_idMemo = GUICtrlCreateEdit("", 2, 72, 396, 226, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    ; Ajoute des chaînes
    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x, $x)
    Next

    ; Sélectionne une chaîne
    _GUICtrlComboBoxEx_SetCurSel($hCombo, Random(0, 8, 1))

    ; Modifie la chaîne
    _GUICtrlComboBoxEx_SetEditSel($hCombo, 0, 4)

    ; Obtient Edit Sel
    $aSel = _GUICtrlComboBoxEx_GetEditSel($hCombo)
    MemoWrite(StringFormat("Selected: [%d][%d]", $aSel[0], $aSel[1]))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite