UDF > GUI > GuiComboBoxEx >

_GUICtrlComboBoxEx_SetDroppedWidth

Définit la largeur maximale admissible, en pixels, de la zone de liste d'une ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetDroppedWidth ( $hWnd, $iWidth )

Paramètres

$hWnd Handle du contrôle
$iWidth La largeur de la zone de liste, en pixels,

Valeur de retour

Succès: Retourne la nouvelle largeur de la zone de liste.
Échec: Retourne -1.

Remarques

Par défaut, la largeur minimale admissible de la zone de liste déroulante est 0.
La largeur de la zone de liste est soit la largeur minimale admissible, soit la largeur de la ComboBox, si elle est plus grande.

Utiliser le style $$CBS_DROPDOWN ou $CBS_DROPDOWNLIST.

En relation

_GUICtrlComboBoxEx_GetDroppedWidth

Exemple

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hImage, $hCombo

    ; Crée une GUI
    $hGUI = GUICreate("ComboBoxEx Set Dropped Width", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x, $x)
    Next

    ; Obtient la largeur déroulée
    MemoWrite("Dropped Width......: " & _GUICtrlComboBoxEx_GetDroppedWidth($hCombo))

    Sleep(500)

    ; Montre la liste déroulane
    _GUICtrlComboBoxEx_ShowDropDown($hCombo, True)

    Sleep(500)

    ; Cache la liste déroulane
    _GUICtrlComboBoxEx_ShowDropDown($hCombo)

    ; Définit la largeur déroulée
    _GUICtrlComboBoxEx_SetDroppedWidth($hCombo, 500)

    Sleep(500)

    ; Obtient la largeur de la liste déroulante
    MemoWrite("Dropped Width......: " & _GUICtrlComboBoxEx_GetDroppedWidth($hCombo))

    Sleep(500)

    ; Montre la liste déroulante
    _GUICtrlComboBoxEx_ShowDropDown($hCombo, True)

    Sleep(500)

    ; Cache la liste déroulante
    _GUICtrlComboBoxEx_ShowDropDown($hCombo)

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite