UDF > GUI > GuiComboBoxEx >

_GUICtrlComboBoxEx_GetExtendedUI

Détermine si un ComboBoxEx a l'interface utilisateur par défaut ou l'interface utilisateur étendue

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetExtendedUI ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

True: Le ComboBox a l'interface utilisateur étendue.
False: Le ComboBox n'a PAS l'interface utilisateur étendue.

Remarques

Par défaut, la touche F4 ouvre ou ferme la liste et la flèche vers le bas modifie la sélection courante.

Dans un ComboBox avec l'interface utilisateur avancée, la touche F4 est désactivée en l'appuie sur la flèche vers le bas ouvre la liste déroulante

En relation

_GUICtrlComboBoxEx_SetExtendedUI

Exemple

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hImage, $hCombo

    ; Crée une GUI
    $hGUI = GUICreate("ComboBoxEx Get Extended UI", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x, $x)
    Next

    ; Obtient Extended UI
    MemoWrite("Extended UI: " & _GUICtrlComboBoxEx_GetExtendedUI($hCombo))

    ; Définit Extended UI
    _GUICtrlComboBoxEx_SetExtendedUI($hCombo, True)

    ; Obtient Extended UI
    MemoWrite("Extended UI: " & _GUICtrlComboBoxEx_GetExtendedUI($hCombo))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite