UDF > GUI > GuiButton >

_GUICtrlButton_GetIdealSize

Obtient la taille du bouton qui correspond le mieux à son texte et son image, si une liste d'images est présente

#include <GuiButton.au3>
_GUICtrlButton_GetIdealSize ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Retourne un tableau contenant les éléments suivants:
    [0] - Largeur idéale
    [1] - Hauteur idéale

En relation

_GUICtrlButton_SetSize

Voir aussi

Consultez BCM_GETIDEALSIZE dans la librairie MSDN.

Exemple

#include <GuiButton.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hImage, $idBtn, $aIdealSize

    GUICreate("Buttons", 400, 400)
    $g_idMemo = GUICtrlCreateEdit("", 119, 10, 276, 374, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")

    $hImage = _GUIImageList_Create(32, 32, 5, 3, 6)
    For $x = 6 To 11
        _GUIImageList_AddIcon($hImage, "shell32.dll", $x, True)
    Next

    $idBtn = GUICtrlCreateButton("Button1", 10, 10, 90, 50)
    _GUICtrlButton_SetImageList($idBtn, $hImage)

    GUISetState(@SW_SHOW)

    $aIdealSize = _GUICtrlButton_GetIdealSize($idBtn)
    MemoWrite("Button1 Ideal width: " & $aIdealSize[0] & " height: " & $aIdealSize[1])

    Sleep(3000)

    MemoWrite(StringFormat("Set Size: %s", _GUICtrlButton_SetSize($idBtn, $aIdealSize[0], $aIdealSize[1])))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite