UDF > GUI > GuiAVI >

_GUICtrlAVI_Show

Affiche/Masque le contrôle AVI

#include <GuiAVI.au3>
_GUICtrlAVI_Show ( $hWnd, $iState )

Paramètres

$hWnd ID/handle du contrôle
$iState Etat de l'AVI, peut prendre les valeurs suivantes:

Valeur de retour

Succès: Retourne True - le contrôle était auparavant visible.
Retourne False - le contrôle était auparavant caché.
Échec: @error <> 0.

Exemples

Exemple 1

; Utilisation d'une Fonction AutoIt

#include <GuiAVI.au3>
#include <GUIConstantsEx.au3>

_Example_Internal()

Func _Example_Internal()
    Local $id_AVI, $id_Start, $id_Stop, $id_Show

    ; Crée une GUI
    GUICreate("(Internal) AVI Play", 350, 200)
    $id_AVI = GUICtrlCreateAvi(@SystemDir & "\shell32.dll", 160, 10, 10)
    $id_Start = GUICtrlCreateButton("start", 25, 150, 70, 22)
    $id_Stop = GUICtrlCreateButton("stop", 125, 150, 70, 22)
    $id_Show = GUICtrlCreateButton("hide", 225, 150, 70, 22)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $id_Start
                ; Joue une partie du clip AVI
                _GUICtrlAVI_Play($id_AVI)
            Case $id_Stop
                ; Arrête le clip AVI
                _GUICtrlAVI_Stop($id_AVI)
            Case $id_Show
                If GUICtrlRead($id_Show) = "hide" Then
                    _GUICtrlAVI_Show($id_AVI, @SW_HIDE)
                    GUICtrlSetData($id_Show, "show")
                Else
                    _GUICtrlAVI_Show($id_AVI, @SW_SHOW)
                    GUICtrlSetData($id_Show, "hide")
                EndIf
        EndSwitch
    WEnd

    ; Ferme le clip AVI
    _GUICtrlAVI_Close($id_AVI)

    GUIDelete()
EndFunc   ;==>_Example_Internal

Exemple 2

#include <GuiAVI.au3>
#include <GUIConstantsEx.au3>

_Example_External()

Func _Example_External()
    Local $hGUI, $hAVI, $id_Start, $id_Stop, $id_Show

    ; Crée une GUI
    $hGUI = GUICreate("(External) AVI Play", 350, 200)
    $hAVI = _GUICtrlAVI_Create($hGUI, @SystemDir & "\Shell32.dll", 160, 10, 10)
    $id_Start = GUICtrlCreateButton("start", 25, 150, 70, 22)
    $id_Stop = GUICtrlCreateButton("stop", 125, 150, 70, 22)
    $id_Show = GUICtrlCreateButton("hide", 225, 150, 70, 22)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Local $iMsg
    Do
        $iMsg = GUIGetMsg()
        Switch $iMsg
            Case $id_Start
                ; Joue une partie du clip AVI
                _GUICtrlAVI_Play($hAVI)
            Case $id_Stop
                ; Arrête le clip AVI
                _GUICtrlAVI_Stop($hAVI)
            Case $id_Show
                If GUICtrlRead($id_Show) = "hide" Then
                    _GUICtrlAVI_Show($hAVI, @SW_HIDE)
                    GUICtrlSetData($id_Show, "show")
                Else
                    _GUICtrlAVI_Show($hAVI, @SW_SHOW)
                    GUICtrlSetData($id_Show, "hide")
                EndIf
        EndSwitch
    Until $iMsg = $GUI_EVENT_CLOSE

    ; Ferme le clip AVI
    _GUICtrlAVI_Close($hAVI)

    GUIDelete()
EndFunc   ;==>_Example_External