UDF > GUI > GuiAVI >

_GUICtrlAVI_Play

Joue un clip AVI dans un contrôle animation

#include <GuiAVI.au3>
_GUICtrlAVI_Play ( $hWnd [, $iFrom = 0 [, $iTo = -1 [, $iRepeat = -1]]] )

Paramètres

$hWnd	ID/handle du contrôle
$iFrom	[optionnel] Index, à partir de 0, de l'image où la lecture doit commencer. La valeur doit être inférieure à 65 536. Une valeur de 0 correspond à la première image du clip.
$iTo	[optionnel] Index, à partir de 0, de l'image où la lecture se termine. La valeur doit être inférieure à 65 536. Une valeur de -1 correspond à la dernière image du clip.
$iRepeat	[optionnel] Nombre de fois que le clip AVI sera rejoué. Une valeur de -1 signifie rejouer le clip indéfiniment.

Valeur de retour

Succès:	Retourne True.
Échec:	Retourne False.

Remarque

Le contrôle joue le clip en arrière-plan pendant que le thread continue de s'exécuter.

En relation

_GUICtrlAVI_Seek, _GUICtrlAVI_Stop

Exemples

Exemple 1

; Utilisation d'une fonction AutoIt

#include <GuiAVI.au3>
#include <GUIConstantsEx.au3>

_Example_Internal()

Func _Example_Internal()
    Local $idAVI, $id_Start, $id_Stop

    ; Crée une GUI
    GUICreate("(Internal) AVI Play/Stop", 300, 200)
    $idAVI = GUICtrlCreateAvi(@SystemDir & "\shell32.dll", 160, 10, 10)
    $id_Start = GUICtrlCreateButton("start", 50, 150, 70, 22)
    $id_Stop = GUICtrlCreateButton("stop", 150, 150, 70, 22)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $id_Start
                ; Joue une partie du clip AVI
                _GUICtrlAVI_Play($idAVI)
            Case $id_Stop
                ; Arrête le clip AVI
                _GUICtrlAVI_Stop($idAVI)
        EndSwitch
    WEnd

    ; Ferme le clip AVI
    _GUICtrlAVI_Close($idAVI)

    GUIDelete()
EndFunc   ;==>_Example_Internal

Exemple 2

; Utilisation d'une UDF

#include <GuiAVI.au3>
#include <GUIConstantsEx.au3>

_Example_External()

Func _Example_External()
    Local $hGUI, $hAVI, $id_Start, $id_Stop

    ; Crée une GUI
    $hGUI = GUICreate("(External) AVI Play/Stop", 300, 200)
    $hAVI = _GUICtrlAVI_Create($hGUI, @SystemDir & "\Shell32.dll", 160, 10, 10)
    $id_Start = GUICtrlCreateButton("start", 50, 150, 70, 22)
    $id_Stop = GUICtrlCreateButton("stop", 150, 150, 70, 22)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Local $iMsg
    Do
        $iMsg = GUIGetMsg()
        Switch $iMsg
            Case $id_Start
                ; Joue une partie du clip AVI
                _GUICtrlAVI_Play($hAVI)
            Case $id_Stop
                ; Arrête un clip AVI
                _GUICtrlAVI_Stop($hAVI)
        EndSwitch
    Until $iMsg = $GUI_EVENT_CLOSE

    ; Ferme un clip AVI
    _GUICtrlAVI_Close($hAVI)

    GUIDelete()
EndFunc   ;==>_Example_External