Functions > GUI > GUICtrlCreate >

GUICtrlCreateAvi

Crée un contrôle vidéo AVI pour une GUI.

GUICtrlCreateAvi ( filename, subfileid, left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

Paramètres

filename Le nom du fichier vidéo. Seuls les fichiers .avi sont pris en charge.
subfileid ID du sous-fichier à utiliser. Si le fichier contient une seule vidéo alors utilisez -1.
left Coordonnée X du coin supérieur gauche du contrôle. Si égal à -1, alors X sera calculée en fonction de GUICoordMode.
top Coordonnée Y du coin supérieur gauche du contrôle. Si égal à -1, alors Y sera calculé en fonction de GUICoordMode.
width [optionnel] Largeur du contrôle (par défaut, la largeur utilisée précédemment).
height [optionnel] Hauteur du contrôle (par défaut, la hauteur utilisée précédemment).
style [optionnel] Définit le style du contrôle. Consultez l'Annexe des styles des contrôles GUI.
    Par défaut (-1) : $ACS_TRANSPARENT
    $ACS_TRANSPARENT est toujours utlisé à moins que $ACS_NONTRANSPARENT soit spécifié.
exStyle [optionnel] Définit le style étendu du contrôle. Consultez Tableau des Styles étendus.

Valeur de retour

Succès: Retourne l'ID du nouveau contrôle.
Échec: Retourne 0.

Remarques

Pour obtenir la valeur du contrôle, consultez GUICtrlRead.
Pour définir ou modifier des informations dans le contrôle, Consultez GUICtrlUpdate....

Pour lancer la vidéo dès que le contrôle est créé utilisez le style $ACS_AUTOPLAY.
Vous pouvez démarrer et arrêter la vidéo en définissant l'état à 1 ou 0 avec GUICtrlSetState. Consultez l'exemple.

Pour combiner les styles avec l'utilisation de style par défaut BitOR($GUI_SS_DEFAULT_AVI, newstyle, ...).

Pour utiliser les valeurs spécifiées ci-dessus, vous devez préciser #include <AVIConstants.au3> dans votre script.
Le redimensionnement par défaut est $GUI_DOCKSIZE.

En relation

GUICoordMode (option), GUICtrlUpdate..., GUIGetMsg

Exemple

#include <GUIConstantsEx.au3>

Example()

Func Example()
    ; Crée une GUI avec différents contrôles.
    Local $hGUI = GUICreate("Example", 300, 200)

    ; Crée un contrôle vidéo.
    Local $idAnimation = GUICtrlCreateAvi(@SystemDir & "\shell32.dll", 165, 15, 0, 300)
    Local $idStart = GUICtrlCreateButton("Start", 60, 150, 85, 25)
    Local $idStop = GUICtrlCreateButton("Stop", 160, 150, 85, 25)

    ; Affiche la GUI.
    GUISetState(@SW_SHOW, $hGUI)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Local $idMsg = GUIGetMsg() 
 
    While $idMsg <> $GUI_EVENT_CLOSE
        Switch $idMsg
             Case $idStart ; Lance l'animation.
                GUICtrlSetState($idAnimation, $GUI_AVISTART)

            Case $idStop ; Arrête l'animation.
                GUICtrlSetState($idAnimation, $GUI_AVISTOP)
        EndSwitch
        $idMsg = GUIGetMsg()
    WEnd

    ; Supprime la GUI précédente et tous ses contrôles.
    GUIDelete($hGUI)
EndFunc   ;==>Example