UDF > GUI > GuiAVI >

_GUICtrlAVI_Seek

Affiche une image particulière d'un clip AVI

#include <GuiAVI.au3>
_GUICtrlAVI_Seek ( $hWnd, $iFrame )

Paramètres

$hWnd ID/handle du contrôle
$iFrame Index, à partir de 0, de l'image à afficher

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlAVI_Play

Exemples

Exemple 1

; Utilisation d'une Fonction AutoIt

#include <GuiAVI.au3>
#include <GUIConstantsEx.au3>

_Example_Internal()

Func _Example_Internal()
    ; Crée une GUI
    GUICreate("(Internal) AVI Seek", 300, 100)
    Local $idAVI = GUICtrlCreateAvi(@SystemDir & "\shell32.dll", 160, 10, 10)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
        Sleep(100)
        ; Cherche une image aléatoire dans le clip AVI
        _GUICtrlAVI_Seek($idAVI, Random(1, 30, 1))
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Ferme le clip AVI
    _GUICtrlAVI_Close($idAVI)

    GUIDelete()
EndFunc   ;==>_Example_Internal

Exemple 2

; Utilisation d'une UDF standard

#include <GuiAVI.au3>
#include <GUIConstantsEx.au3>

_Example_External()

Func _Example_External()
    Local $hGUI, $hAVI

    ; Crée une GUI
    $hGUI = GUICreate("(External) AVI Seek", 300, 100)
    $hAVI = _GUICtrlAVI_Create($hGUI, @SystemDir & "\Shell32.dll", 160, 10, 10)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
        Sleep(100)
        ; Cherche une image aléatoire dans le clip AVI
        _GUICtrlAVI_Seek($hAVI, Random(1, 30, 1))
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Ferme le clip AVI
    _GUICtrlAVI_Close($hAVI)

    GUIDelete()
EndFunc   ;==>_Example_External